带有多个变量的SPSS折线图

Question

如何使用3个变量的频率分布构建折线图？它们具有相似的值范围。我在Windows 8.1下使用SPSS 19 basic。

由于

Answer 1

以下是重塑数据的示例，以便所有三个变量位于同一列中，然后将这些行映射到不同的颜色。所以首先让我们制作一些假数据。

SET SEED 10.
INPUT PROGRAM.
LOOP #i = 1 TO 100.
  COMPUTE X = #i.
  COMPUTE Y1 = RV.NORMAL(2,1).
  COMPUTE Y2 = RV.NORMAL(7,1).
  COMPUTE Y3 = RV.NORMAL(12,1).
  END CASE.
END LOOP.
END FILE.
END INPUT PROGRAM.

现在可以在数据的当前形状中制作您想要的图表，但通常有用的方法是重新整形数据，以便所有三个Y变量位于同一列并且具有第二个分类变量Var，区分原始变量。 （FORMATS命令是在此示例中使图表中的标签看起来更好。）

VARSTOCASES /MAKE Y FROM Y1 TO Y3 /INDEX Var (Y).
FORMATS X Y (F3.0).

现在我们可以构建图形，这非常接近GUI吐出的内容（我编辑Y轴的最小值为-1）。

GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=X Y Var 
    MISSING=LISTWISE REPORTMISSING=NO
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
  SOURCE: s=userSource(id("graphdataset"))
  DATA: X=col(source(s), name("X"))
  DATA: Y=col(source(s), name("Y"))
  DATA: Var=col(source(s), name("Var"), unit.category())
  GUIDE: axis(dim(1), label("X"))
  GUIDE: axis(dim(2), label("Y"))
  GUIDE: legend(aesthetic(aesthetic.color.interior), label("Var"))
  SCALE: linear(dim(2), min(-1))
  ELEMENT: line(position(X*Y), color.interior(Var))
END GPL.