Question

我在我的应用中使用 Rails 4.1.4 。我有一个 delete 方法的链接，该方法具有 data-confirm 属性，因此在继续操作之前会出现确认对话框。

<%= link_to t(:delete_account), delete_account_path, method: :delete, class: "btn btn-danger btn-sm", data: { confirm: t(:delete_account_confirmation_text) } %>

出现的确认对话框是浏览器的默认值。如何自定义此项以使用 Bootstrap 模式？例如？

问候!!!

Answer 1

使用一些自定义coffeescript，例如：

$ ->
  $.rails.allowAction = (link) ->
    return true unless link.attr('data-confirm')
    $.rails.showConfirmDialog(link) 
    false 

  $.rails.confirmed = (link) ->
    link.removeAttr('data-confirm')
    link.trigger('click.rails')

  $.rails.showConfirmDialog = (link) ->
    message = link.attr 'data-confirm'
    html = """
           <div class="modal" id="confirmationDialog">
             <div class="modal-dialog">
               <div class="modal-content">
                 <div class="modal-header">
                   <a class="close" data-dismiss="modal">×</a>
                   <h1>#{message}</h1>
                 </div>
                 <div class="modal-footer">
                   <a data-dismiss="modal" class="btn">#{link.data('cancel')}</a>
                   <a data-dismiss="modal" class="btn btn-primary confirm">#{link.data('ok')}</a>
                 </div>
               </div>
             </div>
           </div>
           """
    $(html).modal()
    $('#confirmationDialog .confirm').on 'click', -> $.rails.confirmed(link)

这也可以立即翻译你的确定和取消按钮，比如

data: { confirm: t('messages.confirm_delete'), ok: t('buttons.ok'), cancel: t('buttons.cancel')

如果您不想总是重复此操作，请使用一些助手来创建自定义“删除链接”！

Answer 2

您可以尝试使用gem (data-confirm-modal)。

Rails 4.1.4自定义确认警报

2 个答案: