Question

我有一个托管类库（比如说mylib.dll）和一个使用mylib.dll的第三方托管应用程序（比如app.exe）。我有mylib.dll的代码但不是app.exe的代码。所以我目前所做的是构建mylib.dll，将其复制到app.exe的目录，启动app.exe并附加到进程。这样，如果我在代码mylib.dll中放置断点，我看到它们被击中。但是，无论何时任何外部应用程序调用其公开的方法之一，都会自动中断mylib.dll的代码吗？即。仅适用于dll的入口点。

感谢，米沙勒

Answer 1

在项目下 - ＆gt;属性 - ＆gt;调试 - ＆gt;启动操作您应指定选项启动外部程序并输入app.exe的路径。这应该启动附带调试器的app.exe。

另见How to: Change the Start Action for Application Debugging

更新：Visual Studio中的断点要么绑定到某个位置（即源文件中的特定代码行），要么绑定到函数名称。因此，基本上有两个选项可以在程序集中的函数被调用时中断：在所有函数声明或所有函数名称上放置断点（ Debug - ＆gt; New Breakpoint - ＆gt; Break on Function Name ）。不幸的是，后一个选项需要完整的函数名称，并且不允许使用通配符。

您可以考虑的另一个选择是将Debug.Assert(false)放在所有库函数的开头。

另一种选择是使用Visual Studio宏。下面的宏迭代你的代码DOM并为所有公共方法和属性添加一个断点：

Option Strict Off
Option Explicit Off
Imports System
Imports EnvDTE
Imports EnvDTE80
Imports EnvDTE90
Imports System.Diagnostics
Imports System.Windows.Forms

Public Module Breakpoints

    Sub AddBreakpointsToAllFunctionsAndProperties()
        Try
            If DTE.ActiveSolutionProjects.Length <> 1 Then
                MsgBox("Select one project within the Solution Explorer, then re-run this macro.")
                Exit Sub
            End If

            AddBreakpointsToProject(DTE.ActiveSolutionProjects(0))
        Catch ex As System.Exception
            MessageBox.Show(ex.ToString)
        End Try
    End Sub

    Private Sub AddBreakpointsToProject(ByVal proj As Project)
        For i As Integer = 1 To proj.ProjectItems.Count
            If Not proj.ProjectItems.Item(i).FileCodeModel Is Nothing Then
                AddBreakpointsToProjectItems(proj.ProjectItems.Item(i).FileCodeModel.CodeElements)
            End If
        Next
    End Sub


    Private Sub AddBreakpointsToProjectItems(ByVal colCodeElements As CodeElements)
        Dim objCodeElement As EnvDTE.CodeElement

        If Not (colCodeElements Is Nothing) Then
            For Each objCodeElement In colCodeElements
                AddBreakpointsToProjectItem(objCodeElement)
            Next
        End If
    End Sub

    Private Sub AddBreakpointsToProjectItem(ByVal objCodeElement As CodeElement)

        Dim objCodeNamespace As EnvDTE.CodeNamespace
        Dim objCodeType As EnvDTE.CodeType
        Dim objCodeFunction As EnvDTE.CodeFunction
        Dim objCodeProperty As EnvDTE.CodeProperty

        Try
            'MessageBox.Show(objCodeElement.FullName & " (Kind: " & objCodeElement.Kind.ToString & ")")

            If objCodeElement.Kind = vsCMElement.vsCMElementFunction Then
                objCodeFunction = DirectCast(objCodeElement, EnvDTE.CodeFunction)
                If objCodeFunction.Access = vsCMAccess.vsCMAccessPublic Then
                    DTE.Debugger.Breakpoints.Add(objCodeElement.FullName)
                End If
            ElseIf objCodeElement.Kind = vsCMElement.vsCMElementProperty Then
                objCodeProperty = DirectCast(objCodeElement, EnvDTE.CodeProperty)
                DTE.Debugger.Breakpoints.Add(objCodeElement.FullName)
            End If
        Catch ex As System.Exception
            ' Ignore
        End Try

        If TypeOf objCodeElement Is EnvDTE.CodeNamespace Then
            objCodeNamespace = CType(objCodeElement, EnvDTE.CodeNamespace)
            AddBreakpointsToProjectItems(objCodeNamespace.Members)
        ElseIf TypeOf objCodeElement Is EnvDTE.CodeType Then
            objCodeType = CType(objCodeElement, EnvDTE.CodeType)
            AddBreakpointsToProjectItems(objCodeType.Members)
        ElseIf TypeOf objCodeElement Is EnvDTE.CodeFunction Then
            objCodeFunction = DirectCast(objCodeElement, EnvDTE.CodeFunction)
            AddBreakpointsToProjectItems(CType(objCodeElement, CodeFunction).Parameters)
        End If
    End Sub

End Module

Answer 2

我没有在类库中尝试过，但这可能有用。

System.Diagnostics.Debugger.Break();

Answer 3

我不认为只要它被调用就会自动中断代码。

断点仅在调试器中有效，因此您必须以某种方式在调试器中运行所有应用程序。

你想通过这个来实现什么？

您是否只想知道您的图书馆何时被召集？如果是这样，只需将日志记录添加到您的入口点。

如果您对特定应用程序有特定问题，请遵循0xA3给出的建议。

Answer 4

System.Diagnostics.Debugger.Launch();也是一种选择。

当我的类库函数被调用时，有没有办法自动进入调试器？

4 个答案: