Question

我正在处理此处理说明：<?Pub _kern Amount="-25pt"?>

使用：

<xsl:template match="processing-instruction('Pub')">
        <xsl:choose>
            <xsl:when test="starts-with(., '_kern')">
                <xsl:attribute name="style"><xsl:text>padding-left: </xsl:text>
                <xsl:value-of select="if (contains(.,'Amount')) then (substring-before(substring-after(., 'Amount=&quot;'), '&quot;')) else '12pt'"/>
                </xsl:attribute>
            </xsl:when>
        </xsl:choose>
</xsl:template>

但这仅在PI位于<div>等容器元素内时才有效。我收到错误，因为XSLT试图将样式标记添加到不存在的父元素。如果我在<span>之前添加了<xsl:attribute name="style">，则当PI位于容器元素内时代码不起作用。如何检测是否有容器元素，以便我知道是否添加跨度？除非有更好的方法，否则我是XSLT的初学者。

Answer 1

您可以通过添加简单条件来检查处理指令是否具有父元素

 <xsl:template match="processing-instruction('Pub')[parent::*]">

但要小心，如果您的XML看起来像这样：

<div>
   <?Pub _kern Amount="-25pt"?>    
</div>

如果首先匹配并复制了空白文本节点，则可能仍会出现错误。您可能需要在XSLT中包含xsl:strip-space命令。

例如，这会出错

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:template match="processing-instruction('Pub')[parent::*]">
            <xsl:choose>
                <xsl:when test="starts-with(., '_kern')">
                    <xsl:attribute name="style"><xsl:text>padding-left: </xsl:text>
                    <xsl:value-of select="if (contains(.,'Amount')) then (substring-before(substring-after(., 'Amount=&quot;'), '&quot;')) else '12pt'"/>
                    </xsl:attribute>
                </xsl:when>
            </xsl:choose>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

但这并不......

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:strip-space elements="*" />

    <xsl:template match="processing-instruction('Pub')[parent::*]">
            <xsl:choose>
                <xsl:when test="starts-with(., '_kern')">
                    <xsl:attribute name="style"><xsl:text>padding-left: </xsl:text>
                    <xsl:value-of select="if (contains(.,'Amount')) then (substring-before(substring-after(., 'Amount=&quot;'), '&quot;')) else '12pt'"/>
                    </xsl:attribute>
                </xsl:when>
            </xsl:choose>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

编辑：在回复您的评论时，即使使用xsl:strip-space，如果在处理指令之前有前一个兄弟，您仍然会收到错误

<div>
    <text></text>
    <?Pub _kern Amount="-25pt"?>    
</div>

这是因为如果父元素已经输出子节点，则无法将属性添加到父元素。

如果打算尝试将属性添加到父级，但如果不创建span标记，则可以将匹配处理指令的模板格式更改为：

<xsl:template match="processing-instruction('Pub')">
    <xsl:choose>
        <xsl:when test="not(parent::*) or preceding-sibling::node()">
            <span>
                <!-- Add attribute -->
            </span>
        </xsl:when>
        <xsl:otherwise>
            <!-- Add attribute -->
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

可以在模板中添加属性以避免重复编码。试试这个XSLT：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:strip-space elements="*" />

    <xsl:template match="processing-instruction('Pub')">
        <xsl:choose>
            <xsl:when test="not(parent::*) or preceding-sibling::node()">
                <span>
                    <xsl:call-template name="processing-instruction"/>
                </span>
            </xsl:when>
            <xsl:otherwise>
                <xsl:call-template name="processing-instruction"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template name="processing-instruction">
        <xsl:choose>
            <xsl:when test="starts-with(., '_kern')">
                <xsl:attribute name="style"><xsl:text>padding-left: </xsl:text>
                <xsl:value-of select="if (contains(.,'Amount')) then (substring-before(substring-after(., 'Amount=&quot;'), '&quot;')) else '12pt'"/>
                </xsl:attribute>
            </xsl:when>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Answer 2

这很有效，如果没有@Tim C的帮助，我就不会这样做：

<xsl:template match="processing-instruction('Pub')">
    <xsl:choose>
        <xsl:when test="starts-with(., '_kern') and processing-instruction()[parent::*]">
            <xsl:attribute name="style"><xsl:text>padding-left: </xsl:text>
            <xsl:value-of select="if (contains(.,'Amount')) then (substring-before(substring-after(., 'Amount=&quot;'), '&quot;')) else '12pt'"/>
            </xsl:attribute>
        </xsl:when>
        <xsl:when test="starts-with(., '_kern')">
            <span><xsl:attribute name="style"><xsl:text>padding-left: </xsl:text>
            <xsl:value-of select="if (contains(.,'Amount')) then (substring-before(substring-after(., 'Amount=&quot;'), '&quot;')) else '12pt'"/>
            </xsl:attribute></span>
        </xsl:when>
        <xsl:otherwise/>
    </xsl:choose>
</xsl:template>

它可能不完全正确，但它完成了工作。

检查是否存在用于处理指令的容器元素

2 个答案: