Question

我正在尝试将XML文件中的几个孩子复制到另一个XML文件中。我创建了一个适用于命名元素的白名单，但是当我尝试限制一个也是孩子的单个属性名称值对时，我找不到匹配。

示例XML：

<?xml version="1.0" encoding="UTF-8"?>
<catalog catalog-id="Primary">
    <product product-id="COLAKIT">
        <ean/>
        <upc/>
        <unit>SKU</unit>
        <custom-attributes>
            <custom-attribute attribute-id="Base_Color">Brown</custom-attribute>
            <custom-attribute attribute-id="Shipping_Cost">0.0</custom-attribute>
            <custom-attribute attribute-id="showEstimatedDelivery">false</custom-attribute>
        </custom-attributes>
        <classification-category>Kitchen_Housewares-Coffee_and_Tea</classification-category>
    </product>

    <product product-id="COLONIAL-48-M-K">
        <ean/>
        <upc/>
        <unit>SKU</unit>
        <custom-attributes>
            <custom-attribute attribute-id="Base_Color">Coffee</custom-attribute>
            <custom-attribute attribute-id="Shipping_Cost">0.0</custom-attribute>
            <custom-attribute attribute-id="showEstimatedDelivery">false</custom-attribute>
        </custom-attributes>
        <classification-category>Outdoor_Living-Heaters-Fireplaces</classification-category>
    </product>

</catalog>

XSLT：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ns="some:ns">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>

 <ns:WhiteList>
  <name>classification-category</name>
  <name>custom-attribute[attribute-id()='Shipping_Cost']</name>
 </ns:WhiteList>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="*[not(descendant-or-self::*[name()=document('')/*/ns:WhiteList/*])]"/>
</xsl:stylesheet>

此外，主XML有100个节点，我只想要3，这就是我尝试白名单而不是排除的原因。请通过attribute = value match让我知道我缺少什么。

Answer 1

您的方法存在的问题是"custom-attribute[attribute-id()='Shipping_Cost']"不是名称。它甚至不是（在你的情况下）一个XPath表达式;它是一个字符串 - 你需要一个扩展函数（或XSLT 3.0）来评估它作为XPath。您必须更改它才能评估为有效 XPath，即使用@attribute-id代替attribute-id()。

您的方法面临的更大问题是效率非常低。在XSLT中，明确是值得的，特别是如果您正在谈论数百个节点。而不是构建一个＆＃34; side-way＆＃34;白名单，考虑更直接的方法：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<!-- "white list" -->
<xsl:template match="product">
    <xsl:copy>
        <xsl:copy-of select="@product-id"/>
        <xsl:copy-of select="classification-category"/>
        <xsl:copy-of select="custom-attributes/custom-attribute[@attribute-id='Shipping_Cost']"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Answer 2

当然，您上面使用的尝试不起作用，因为您的源文档没有名称为custom-attribute[attribute-id()='Shipping_Cost']的任何元素（同样，没有名称为{{的XPath函数） 1}}）。

标准XSLT 1.0无法根据XML中存在的字符串值来评估XPath，因此我认为您可能需要采用一种比您希望的方法更不通用的方法。这是一种这样的方法：

attribute-id()

Answer 3

可以在XSLT 1.0中处理对排序的动态评估，但它将涉及进行两次转换。它利用了XSLT格式良好的XML这一事实，这意味着您可以使用XSLT将其转换为其他XSLT。一个＆＃34; XSLT写自己的案例＆＃34;。

这个想法是你有一个预处理步骤，将你当前的XSLT转换为新的改进版XSLT，包括你的动态＆＃39;表达式，然后将其应用于XML：

您可以先将当前的XSLT更改为：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ns="some:ns">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>

 <ns:WhiteList>
  <name>classification-category</name>
  <name>custom-attribute[@attribute-id = 'Shipping_Cost']</name>
 </ns:WhiteList>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

对于第一次预处理＆＃39;在转换步骤中，您将拥有一个由身份模板组成的XSLT，但也有一个匹配xsl:styleheet并复制它的模板，但还添加了一个新的xsl:template指令，其match属性是根据您ns:WhiteList

的信息构建的

这是预处理XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0" xmlns:xslOut="xlst.temp" xmlns:ns="some:ns">
    <xsl:output method="xml" encoding="UTF-8" indent="yes" />

    <xsl:namespace-alias stylesheet-prefix="xslOut" result-prefix="xsl"/>

    <xsl:template match="/xsl:stylesheet">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>

            <xslOut:template>
                <xsl:attribute name="match">
                    <xsl:text>*[</xsl:text>
                    <xsl:for-each select="ns:WhiteList/name">
                        <xsl:if test="position() > 1"> and </xsl:if>
                        <xsl:text>not(descendant-or-self::</xsl:text>
                        <xsl:value-of select="." />
                        <xsl:text>)</xsl:text>
                    </xsl:for-each>
                    <xsl:text>]</xsl:text>
                </xsl:attribute>
            </xslOut:template>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="ns:WhiteList" />

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

请注意，此处使用xsl:namespace-alias字面输出xslt元素（如果您尝试将<xslOut:template>替换为<xsl:template>，则会导致错误。

当预处理XSLT应用于初始XSLT时，生成此修改后的XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:ns="some:ns"
                version="1.0">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>

   <xsl:template match="node()|@*">
     <xsl:copy>
         <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
   </xsl:template>
   <xsl:template match="*[not(descendant-or-self::classification-category) and not(descendant-or-self::custom-attribute[@attribute-id = 'Shipping_Cost'])]"/>
</xsl:stylesheet>

然后，您可以将此生成的XSLT应用于XML，以输出以下内容：

<catalog catalog-id="Primary">
   <product product-id="COLAKIT">
      <custom-attributes>
         <custom-attribute attribute-id="Shipping_Cost">0.0</custom-attribute>
      </custom-attributes>
      <classification-category>Kitchen_Housewares-Coffee_and_Tea</classification-category>
   </product>
   <product product-id="COLONIAL-48-M-K">
      <custom-attributes>
         <custom-attribute attribute-id="Shipping_Cost">0.0</custom-attribute>
      </custom-attributes>
      <classification-category>Outdoor_Living-Heaters-Fireplaces</classification-category>
   </product>
</catalog>

XSLT Copy受属性值对的限制

3 个答案: