Question

我正在尝试为源XML编写XSLT文档，我也有Traget XML（它应该是什么样子）

My Source看起来像：

<soap:Envelope xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
 <soap:Body>
<a xmlns="http://schemas.microsoft.com/sharepoint/soap/directory/">
  <b>
    <c>
      <d>
        <e MemberID="1" />
        <e MemberID="2" />
        <e MemberID="3" />
       </d>
    </c>
  </b>
</a>
</soap:Body>
</soap:Envelope>

我想要实现的是（目标XML）

<d>
   <e ID="1" />
   <e ID="2" />
   <e ID="3" />
</d>

我一直在尝试编写我的XSLT但却无法正常工作。我一直在使用一些在线工具，我给我的源和写XSLT但我没有得到任何结果。（从未在XSLT中工作）

有人可以帮我写这篇文章或者指点我写作方向。

我所尝试的是：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:template match="/">
    <xsl:apply-templates select="a/b/c/d"/>
  </xsl:template>
  <xsl:template match="d">
<d>
  <xsl:for-each select="e">
    <e>
          <xsl:value-of select="@MemberID"/> -- I know its wrong, but just want something to work                  
    </e>
  </xsl:for-each>
</d>
  </xsl:template>
</xsl:stylesheet>

由于

Answer 1

您需要为源文档使用的每个命名空间分配前缀，并在寻址源文档中的元素时使用适当的前缀。这是对样式表的更正：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/"
xmlns:dir="http://schemas.microsoft.com/sharepoint/soap/directory/"
exclude-result-prefixes="soap dir">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:template match="/">
    <xsl:apply-templates select="soap:Envelope/soap:Body/dir:a/dir:b/dir:c/dir:d"/>
</xsl:template> 

<xsl:template match="dir:d">    
    <d>
        <xsl:for-each select="dir:e">
            <e>
                <xsl:value-of select="@MemberID"/>                 
            </e>
        </xsl:for-each>
    </d>
</xsl:template>

</xsl:stylesheet>

这将产生以下结果：

<?xml version="1.0" encoding="utf-8"?>
<d>
  <e>1</e>
  <e>2</e>
  <e>3</e>
</d>

当然，您可以将其简化为：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/"
xmlns:dir="http://schemas.microsoft.com/sharepoint/soap/directory/"
exclude-result-prefixes="soap dir">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:template match="/">
    <d>
        <xsl:for-each select="soap:Envelope/soap:Body/dir:a/dir:b/dir:c/dir:d/dir:e">
            <e>
                <xsl:value-of select="@MemberID"/>                 
            </e>
        </xsl:for-each>
    </d>
</xsl:template> 

</xsl:stylesheet>

要获得所需的输出，请更改：

            <e>
                <xsl:value-of select="@MemberID"/>                 
            </e>

为：

            <e ID="{@MemberID}"/>

需要帮助来创建XSLT，我有源和目标XML

1 个答案: