Question

我有以下代码，此代码是用VB6编写的，但我无法打开表单或检查任何引用。

Private Sub PopulatePrinterCombo(cmbDestination As ComboBox)
  Dim objPrinter  As Printer 'a printer in the Printers collection object

  'Add the printers to the combo box
  For Each objPrinter In printers
    cmbPrinter.AddItem objPrinter.DeviceName
  Next

  'Set current selection to the default printer
  cmbDestination.Text = Printer.DeviceName
End Sub

我目前正在将代码复制到Excel VBA宏上，问题是Dim objPrinter As Printer代码，我不断收到错误消息“USER DEFINED TYPE NOT DEFINED”，我是否需要在VBA上添加引用能够选择将变量声明为“打印机”或什么？

我的第二个问题是我不完全理解For Each objPrinter In printers行中的“打印机”，什么是“打印机”？有人可以向我解释一下。

谢谢

第2部分

我现在正在尝试打印文件，我的代码如下：

  'Initialize values
  intDraftsPrinted = 0
  If objDraftPaths.Count > 1 Then

  Else
    intSelectedDraftCount = CountSelectedDrafts
  End If

  'prompt user to make sure
  intMsgBoxResponse = MsgBox("You selected " & intSelectedDraftCount & " part numbers. After removing duplicates" & vbNewLine & "there were " & objDraftPaths.Count & " unique draft files found." & vbNewLine & "Do you want to print these files?", vbYesNo, "TD Printer")

  If intMsgBoxResponse <> vbYes Then
    intSelectedDraftCount = 0 'So the following for loop will not entered
  Else
    intSelectedDraftCount = objDraftPaths.Count
  End If

  For i = 1 To intSelectedDraftCount

    booSuccess = False

    'open the draft file
    Set objDraftDocument = OpenSolidEdgeDraft(objDraftPaths.Item(i))
    If objDraftDocument Is Nothing Then
      'could not open file
      MsgBox "Could not open the following draft file:" & vbNewLine & _
             objDraftPaths.Item(i), vbExclamation, "Solid Edge Error"
    Else
      'Print the draft file
      For Each objSheet In objDraftDocument.Sheets
        strSheetSize = DetermineSheetSize(objSheet)
        If strSheetSize <> "" Then
          'Determine orientation
          If InStr(1, strSheetSize, "90") <> 0 Then
            'Print as landscape
            intOrientation = vbPRORLandscape

          Else
            'Print as portrait
            intOrientation = vbPRORPortrait
          End If
          'Specify Sheet Size
          Select Case Left(strSheetSize, 1)
            Case "A"
              intPaperSize = VBRUN.PrinterObjectConstants.vbPRPSLetter
            Case "B"
              intPaperSize = VBRUN.PrinterObjectConstants.vbPRPS11x17
            Case "C"
              intPaperSize = VBRUN.PrinterObjectConstants.vbPRPSCSheet
            Case "D"
              intPaperSize = VBRUN.PrinterObjectConstants.vbPRPSDSheet
            Case "E"
              intPaperSize = VBRUN.PrinterObjectConstants.vbPRPSESheet
            Case Else
              intPaperSize = VBRUN.PrinterObjectConstants.vbPRPSLetter
          End Select

          'Enable error handling
          On Error Resume Next

          'Activate the current sheet
          objSheet.Activate
          If Err Then
            'Could not activate sheet
            MsgBox "An error occurred while attempting to print: " & vbNewLine & objDraftPaths.Item(i) & vbNewLine & "The error was:" & vbNewLine & "Error Number: " & Err.Number & vbNewLine & "Error Description: " & Err.Description, vbExclamation, "Solid Edge Error"
            Err.Clear
          Else
            'Print to the printer specified by the combo box
            objDraftDocument.PrintOut cmbPrinter.Text, 1, intOrientation, intPaperSize, , , , igPrintSelected
            If Err Then
              'Could not print document
              MsgBox "An error occurred while attempting to print: " & vbNewLine & objDraftPaths.Item(i) & vbNewLine & "The error was:" & vbNewLine & "Error Number: " & Err.Number & vbNewLine & "Error Description: " & Err.Description, vbExclamation, "Solid Edge Error"
              Err.Clear
            Else
              booSuccess = True
            End If
          End If

          'Disable error handling
          On Error GoTo 0

        End If
      Next

      'Close the file
      objDraftDocument.Close False

      intDraftsPrinted = intDraftsPrinted + 1

    End If

  Next i

  'Dereference objects
  Set objSheet = Nothing
  Set objDraftDocument = Nothing
  'Set objDraftPaths = Nothing

  PrintSelectedDrafts = intDraftsPrinted

现在问题出现了，当我点击说：intOrientation = vbPRORLandscape 在excel VBA中，它不识别“vbPRORLandscape”以及下一行“vbPRORPortrait”。有办法解决这个问题吗？

此外，我感觉VBRUN.PrinterObjectConstants.vbPRPSLetter以及其他行也可能无效。它适用于VB6。

谢谢

Answer 1

Printers集合似乎在MS Access VBA环境中可用，但我不认为它是 Excel VBA环境固有的。

我使用 Windows脚本宿主 的WshNetwork对象列出可用的打印机。我使用下面的子例程使用连接到系统的打印机列表填充ComboBox。为了使此代码有效，您需要添加＆＃34; Windows脚本宿主对象模型＆＃34;参考您的VBA项目。（菜单：工具＆gt;参考[从列表中选择]）

我添加了（j）循环以按字母顺序排列列表。

Sub populatePrintersList()
    Dim nwo As New WshNetwork
    Dim i As Integer
    Dim j As Integer
    Dim bAdd As Boolean

    bAdd = True
    cmbPrinter.Clear
    For i = 0 To (nwo.EnumPrinterConnections.Count / 2) - 1
        For j = 0 To cmbPrinter.ListCount - 1
            If nwo.EnumPrinterConnections(i * 2 + 1) < cmbPrinter.List(j) Then
                cmbPrinter.AddItem nwo.EnumPrinterConnections(i * 2 + 1), j
                bAdd = False
                Exit For
            End If
        Next j
        If bAdd Then cmbPrinter.AddItem nwo.EnumPrinterConnections(i * 2 + 1): bAdd = True
    Next i

    cmbPrinter.ListIndex = 0
End Sub

第2部分：

MSDN包含Worksheet.PrintOut方法的参考资料：Worksheet.PrintOut

有关Worksheet.PageSetup对象的方法和属性的深入文档也可以在MSDN上找到：Worksheet.PageSetup

我建议使用这些资源来寻找过多的答案。

Excel VBA＆amp; VB6打印机

1 个答案: