Question

我正在尝试通过Cmake构建和运行Qt的非常简单和基本的示例，删除.pro文件。以下是Qt项目的代码（自动生成的Qt项目的目录结构是

Cmake (my project name)
├── headers
│   └── mainwindow.h
├── sources
│   ├── main.cpp
│   └── mainwindow.cpp
└── forms
    └── mainwindow.ui

mainwindow.h

#ifndef MAINWINDOW_H
#define MAINWINDOW_H

#include <QMainWindow>

namespace Ui {
class MainWindow;
}

class MainWindow : public QMainWindow
{
    Q_OBJECT

public:
    explicit MainWindow(QWidget *parent = 0);
    ~MainWindow();

private:
    Ui::MainWindow *ui;
};

#endif // MAINWINDOW_H

mainwindow.cpp

#include "mainwindow.h"
#include "ui_mainwindow.h"

MainWindow::MainWindow(QWidget *parent) :
    QMainWindow(parent),
    ui(new Ui::MainWindow)
{
    ui->setupUi(this);
}

MainWindow::~MainWindow()
{
    delete ui;
}

的main.cpp

#include "mainwindow.h"
#include <QApplication>

int main(int argc, char *argv[])
{
    QApplication a(argc, argv);
    MainWindow w;
    w.show();

    return a.exec();
}

这是我的CmakeLists.txt

project(Cmake)

find_package(Qt5Widgets)

set(CMAKE_AUTOMOC ON)
set(CMAKE_INCLUDE_CURRENT_DIR ON)

QT5_WRAP_CPP(Cmake_hdr_moc mainwindow.h)
QT5_WRAP_UI(Cmake_form_hdr mainwindow.ui)

add_library(mainwindow ${Cmake_hdr_moc} ${Cmake_form_hdr})
qt5_use_modules(mainwindow Widgets)

add_executable(Cmake main.cpp mainwindow)
qt5_use_modules(Cmake Core Gui Widgets)

mainwindow.ui

<?xml version="1.0" encoding="UTF-8"?>
<ui version="4.0">
 <class>MainWindow</class>
 <widget class="QMainWindow" name="MainWindow">
  <property name="geometry">
   <rect>
    <x>0</x>
    <y>0</y>
    <width>400</width>
    <height>300</height>
   </rect>
  </property>
  <property name="windowTitle">
   <string>MainWindow</string>
  </property>
  <widget class="QWidget" name="centralWidget"/>
  <widget class="QMenuBar" name="menuBar">
   <property name="geometry">
    <rect>
     <x>0</x>
     <y>0</y>
     <width>400</width>
     <height>29</height>
    </rect>
   </property>
  </widget>
  <widget class="QToolBar" name="mainToolBar">
   <attribute name="toolBarArea">
    <enum>TopToolBarArea</enum>
   </attribute>
   <attribute name="toolBarBreak">
    <bool>false</bool>
   </attribute>
  </widget>
  <widget class="QStatusBar" name="statusBar"/>
 </widget>
 <layoutdefault spacing="6" margin="11"/>
 <resources/>
 <connections/>
</ui>

当我构建项目并运行Cmake时，它指向文件mainwindow.h，表示＆＃39; ui_mainwindow.h＆＃39;没有这样的文件或目录。

Answer 1

您的脚本有几个错误，也可以改进一些。更改后it will be看起来像：

cmake_minimum_required(VERSION 3.0.2)
project(MyProject)

find_package(Qt5Widgets)

set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTOUIC ON)
set(CMAKE_INCLUDE_CURRENT_DIR ON)

add_library(mainwindow mainwindow.cpp)
target_link_libraries (mainwindow Qt5::Widgets)

add_executable(MyProject main.cpp)
target_link_libraries (MyProject mainwindow)

错误：

错误的add_executable指令。您尝试添加库，但为此需要使用target_link_libraries。所以而不是：
```
add_executable(Cmake main.cpp mainwindow)
```
你需要：
```
add_executable(Cmake main.cpp)
target_link_libraries (Cmake mainwindow)
```
还有一个错误是*.cpp指令中缺少add_library个文件：

add_library(mainwindow mainwindow.cpp ${Cmake_hdr_moc} ${Cmake_form_hdr})

建议：

同样设置CMake的版本也是合适的。如果您使用CMAKE_AUTOMOC，则需要不低于2.8.6的版本，如果使用CMAKE_AUTOUIC，则需要不低于3.0.2的版本：
```
cmake_minimum_required(VERSION 3.0.2)
```
不需要将qt5_wrap_cpp与CMAKE_AUTOMOC一起使用。
当您使用CMAKE_AUTOMOC时，使用CMAKE_AUTOUIC代替qt5_wrap_ui会更合适。
此脚本适用于文件系统中具有以下结构的项目：
```
Project
├── CMakeLists.txt
├── main.cpp
├── mainwindow.cpp
├── mainwindow.h
└── mainwindow.ui
```
如果您有其他结构，则应使用 @steveire 中提到的include_directories。
（ UPD ）因为，我已经写了这个答案，我为尝试与Qt到CMake见面的初学者多次提出过建议。他们抱怨项目名称不合适 - “Cmake”。对于刚刚与CMake见面的初学者很难意识到 cmake - 只是项目名称的一部分（并非强制性的），而 cmake 是指令的一部分（并且是强制性的）。所以我想将项目名称从“Cmake”替换为“MyProject”。这减少了问题和答案之间的联系，但另一方面，这使得答案对初学者更友好。
（ UPD ）正如@ErikSjölundqt5_use_modules is obsolete和target_link_libraries所提到的，应该使用它。

注意：就个人而言，我CMAKE_AUTOMOC遇到了不成功的经历;这对于一个结构简单的简单项目来说是件好事。当我的包含文件存储在一个单独的目录中时，我遇到了一个问题：

.
├── include
│   └── QtClass.h
└── src
    └── QtClass.cpp

当具有相同名称的文件进入不同的子目录时：

.
├── NamespaceA
│   ├── QtClass.cpp
│   └── QtClass.h
└── NamespaceB
    ├── QtClass.cpp
    └── QtClass.h

<强>最后：这是基于我个人意见的建议，但我想在不使用CMAKE_AUTOMOC和CMAKE_AUTOUIC的情况下提出脚本more explicit version，它更详细但另一方面你有更多控制：

cmake_minimum_required (VERSION 2.8.12)
project (MyProject)

find_package (Qt5Widgets)

set (MyProjectLib_src ${PROJECT_SOURCE_DIR}/mainwindow.cpp)
set (MyProjectLib_hdr ${PROJECT_SOURCE_DIR}/mainwindow.h)
set (MyProjectLib_ui  ${PROJECT_SOURCE_DIR}/mainwindow.ui)
set (MyProjectBin_src ${PROJECT_SOURCE_DIR}/main.cpp)

qt5_wrap_cpp(MyProjectLib_hdr_moc ${MyProjectLib_hdr})
qt5_wrap_ui (MyProjectLib_ui_moc  ${MyProjectLib_ui})

include_directories (${PROJECT_SOURCE_DIR})
include_directories (${PROJECT_BINARY_DIR})

add_library (MyProjectLib SHARED 
    ${MyProjectLib_src}
    ${MyProjectLib_hdr_moc}
    ${MyProjectLib_ui_moc}
)
target_link_libraries (MyProjectLib Qt5::Widgets)

add_executable(MyProject ${MyProjectBin_src})
target_link_libraries (MyProject MyProjectLib)

项目源代码的完整版本可在GitLab获得。

Answer 2

您没有告诉我们CMakeLists.txt在目录结构中的位置。如果它在顶级，那么你会有

add_executable(Cmake sources/main.cpp sources/mainwindow.cpp)

你需要

include_directories(${CMAKE_CURRENT_SOURCE_DIR}/headers)

无论如何，找出生成ui _ * .h文件的位置，并使用include_directories添加目录。

通过CMake实现Qt项目

2 个答案: