如何使用SPSS使散点图的点半透明？

Question

我用SPSS基础默认散点图制作了这个图：我使用了＆＃34; Bin-element＆＃34;和＆＃34;标记大小＆＃34;重新组合叠加点并使其更易于阅读的选项。这里是 ： http://imageshack.com/a/img902/8746/pTRzJV.jpg

但我希望得到一个看起来像这样的图表： http://espnfivethirtyeight.files.wordpress.com/2014/09/morris-feature-skepticnflweek2-2.png

该图的要点是利用半透明度。我试图找到一些关于不透明度或半透明度的东西，我发现只有这个资源： http://andrewpwheeler.wordpress.com/2012/06/17/visualization-techniques-for-large-n-scatterplots-in-spss/

不幸的是，我不明白该怎么做......你能帮助我吗？

顺便问一下，你知道这张图是用SPSS还是用R做的？对于这种图表哪种工具最好？

谢谢！

Answer 1

这是一个简短的例子。所以首先我会制作一些假数据。

INPUT PROGRAM.
LOOP ID = 1 TO 10000.
END CASE.
END LOOP.
END FILE.
END INPUT PROGRAM.
COMPUTE X = RV.NORMAL(0,1).
COMPUTE Y = RV.NORMAL(0,1).

现在，就我所知，你无法在GUI中生成不透明度 - 你需要在语法中指定它。因此，继续浏览 Graph Builder GUI对话框，指定您感兴趣的散点图，然后粘贴语法。以下是默认为我生成的内容以及图表（使用我的特定图表模板）。

GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=X Y MISSING=LISTWISE REPORTMISSING=NO
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
  SOURCE: s=userSource(id("graphdataset"))
  DATA: X=col(source(s), name("X"))
  DATA: Y=col(source(s), name("Y"))
  GUIDE: axis(dim(1), label("X"))
  GUIDE: axis(dim(2), label("Y"))
  ELEMENT: point(position(X*Y))
END GPL.

现在，您需要编辑倒数第二行的选项ELEMENT语句。我要做两件事; 1）使点更小，2）使点的外部线半透明。这是代码，结果图如下。

GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=X Y MISSING=LISTWISE REPORTMISSING=NO
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
  SOURCE: s=userSource(id("graphdataset"))
  DATA: X=col(source(s), name("X"))
  DATA: Y=col(source(s), name("Y"))
  GUIDE: axis(dim(1), label("X"))
  GUIDE: axis(dim(2), label("Y"))
  ELEMENT: point(position(X*Y), size(size."2"), 
           transparency.exterior(transparency."0.9"))
END GPL.