Question

为什么当它显然将它添加到lst ???时，它总是返回nil

请帮忙！

谢谢！

CL-USER 1 : 1 > (defun constants-aux (form lst)
                  (cond ((null form) lst)
                        ((eq (car form) 'implies) (constants-aux (cdr form) lst))
                        ((eq (car form) 'not) (constants-aux (cdr form) lst))
                        ((eq (car form) 'and) (constants-aux (cdr form) lst))
                        ((eq (car form) 'or) (constants-aux (cdr form) lst))
                        ((atom (car form)) (print (car form)) (cons (car form) (list lst)) (delete-duplicates lst) (constants-aux (cdr form) lst))
                        (T (constants-aux (car form) lst) (constants-aux (cdr form) lst))))
CONSTANTS-AUX

CL-USER 2 : 1 > (defun constants (form)
                   (constants-aux form nil))
CONSTANTS

CL-USER 3 : 1 > constants '(IMPLIES (NOT Q) (IMPLIES Q P))

Q 
Q 
P 
NIL

Answer 1

你在很多方面做错了。

1。 - 当你可以使用可选参数时，为什么要创建-aux函数？

(defun constants (form &optional lst)
  (cond
    ((null form) lst) ...

2. - 你不需要这么多类似的分支，你可以写：

((find (car form) '(implies not and or))
 (constants (cdr form) lst))

3。 - delete-duplicates可能会修改您的列表，但不要认为必须进行修改，即使它会修改，也不会修改您想要的修改。你应该使用它的结果。我认为你甚至有一个STYLE-WARNING，在SBCL中你的代码看起来像这样：

; caught STYLE-WARNING:
;   The return value of DELETE-DUPLICATES should not be discarded.

阅读警告，这有帮助。

我不明白你期望什么结果，所以我不能修改你的功能才能正常工作，但我会试着告诉你问题在哪里。您最后两个cond分支的代码：

((atom (car form))
         (print (car form))
         (cons (car form) (list lst)) ;; Result is ignored
         (delete-duplicates lst)      ;; Result is ignored
         (constants-aux (cdr form) lst))

你应该写：

(constant-aux (cdr form) (delete-duplicates lst))

        (T
           (constants-aux (car form) lst) ;; Result is ignored
           (constants-aux (cdr form) lst))))

可能是（取决于你想得到什么）你应该写：

(cons
   (constants-aux (car form) lst)
   (constants-aux (cdr form) lst))

4 我不是真的，但看起来您使用print进行调试，只需使用trace。对于您的代码，它将为您提供非常好的信息，以便在执行期间列表中发生的事情：

  0: (CONSTANTS-AUX (IMPLIES (NOT Q) (IMPLIES Q P)) NIL)
    1: (CONSTANTS-AUX ((NOT Q) (IMPLIES Q P)) NIL)
      2: (CONSTANTS-AUX (NOT Q) NIL)
        3: (CONSTANTS-AUX (Q) NIL)

Q           4: (CONSTANTS-AUX NIL NIL)
          4: CONSTANTS-AUX returned NIL
        3: CONSTANTS-AUX returned NIL
      2: CONSTANTS-AUX returned NIL
      2: (CONSTANTS-AUX ((IMPLIES Q P)) NIL)
        3: (CONSTANTS-AUX (IMPLIES Q P) NIL)
          4: (CONSTANTS-AUX (Q P) NIL)

Q             5: (CONSTANTS-AUX (P) NIL)

P               6: (CONSTANTS-AUX NIL NIL)
              6: CONSTANTS-AUX returned NIL
            5: CONSTANTS-AUX returned NIL
          4: CONSTANTS-AUX returned NIL
        3: CONSTANTS-AUX returned NIL
        3: (CONSTANTS-AUX NIL NIL)
        3: CONSTANTS-AUX returned NIL
      2: CONSTANTS-AUX returned NIL
    1: CONSTANTS-AUX returned NIL
  0: CONSTANTS-AUX returned NIL

5. 如果您解释一下您希望从此代码中获得什么样的转换，那么回答真的很容易。

祝你好运。

Answer 2

首先要正确格式化你的代码。例如：

(defun constants-aux (form lst)
  (cond ((null form) lst)
        ((eq (car form) 'implies) (constants-aux (cdr form) lst))
        ((eq (car form) 'not)     (constants-aux (cdr form) lst))
        ((eq (car form) 'and)     (constants-aux (cdr form) lst))
        ((eq (car form) 'or)      (constants-aux (cdr form) lst))
        ((atom (car form))
         (print (car form))
         (cons (car form) (list lst))
         (delete-duplicates lst)
         (constants-aux (cdr form) lst))
        (T
         (constants-aux (car form) lst)
         (constants-aux (cdr form) lst))))

然后您可以简化代码：

(defun constants-aux (form list)
  (cond ((null form) list)
        ((member (car form) '(implies not and or))
         (constants-aux (cdr form) list))
        ((atom (car form))
         (constants-aux (cdr form)
                        (adjoin (car form) list)))
        (T
         (constants-aux (car form) list)
         (constants-aux (cdr form) list))))

然后我们可以摆脱car和cdr。

(defun constants-aux (form list)
  (if (consp form)
      (destructuring-bind (head . tail)
          form
        (cond ((member head '(implies not and or))
               (constants-aux tail list))
              ((atom head)
               (constants-aux tail (adjoin head list)))
              (T
               (constants-aux head list)
               (constants-aux tail list))))
    list))

然后你可以对逻辑做一点工作并确保结果不被忽略，确保相邻的东西是正确的，等等......

LISP，cond每次都返回nil

2 个答案: