Question

我是XSLT编程的初学者。我已经完成了转换以下xml的任务：

<Test>TestA::test1</Test>
<Test>TestA::test2</Test>
<Test>TestB::test3</Test>
<Test>TestB::test4</Test>

输出xml应如下所示：

<Class id="TestA">
    <Method id="test1"/>
    <Method id="test2"/>
</Class>
<Class id="TestB">
    <Method id="test3"/>
    <Method id="test4"/>
</Class>

输入xml包含C ++样式的CppUnit测试用例的名称（模式Class :: Method）。我已经尝试了很多不同的方法，并阅读了无数的stackoverflow threds，但无法找到解决方案。

我必须使用XSLT 1.0解决问题。

提前致谢， mexl

Answer 1

这基本上是一个分组问题，由Muenchian grouping解决（在XSLT 1.0中），并且（非常轻微）扭曲。但是，首先您的输入必须具有根元素 - 否则它不是XML文档：

<root>
    <Test>TestA::test1</Test>
    <Test>TestA::test2</Test>
    <Test>TestB::test3</Test>
    <Test>TestB::test4</Test>
</root>

有了这个，下面的样式表：

XSLT 1.0

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:key name="k" match="Test" use="substring-before(., '::')" />

<xsl:template match="/">
    <output>
        <xsl:for-each select="root/Test[count(. | key('k', substring-before(., '::'))[1]) = 1]">
            <Class id="{substring-before(., '::')}">
                <xsl:for-each select="key('k', substring-before(., '::'))">
                     <Method id="{substring-after(., '::')}"/>
                </xsl:for-each>
            </Class>
        </xsl:for-each>
    </output>
</xsl:template>

</xsl:stylesheet>

将返回：

<?xml version="1.0" encoding="UTF-8"?>
<output>
   <Class id="TestA">
      <Method id="test1"/>
      <Method id="test2"/>
   </Class>
   <Class id="TestB">
      <Method id="test3"/>
      <Method id="test4"/>
   </Class>
</output>

Answer 2

使用xsl:key / generate-id，substring-before /substring-after的组合，如下所示：

鉴于

<Tests>
  <Test>TestA::test1</Test>
  <Test>TestA::test2</Test>
  <Test>TestB::test3</Test>
  <Test>TestB::test4</Test>
</Tests>

使用此模板：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output indent="yes" method="xml" encoding="UTF-8"/>

<xsl:key name="testClassKey" match="Test" use="substring-before(., '::')"/>

<xsl:template match="Test" mode="asMethod">
  <xsl:variable name="methodId" select="substring-after(., '::')" />

  <Method id="{$methodId}" />
</xsl:template>


<xsl:template match="Test">
  <xsl:variable name="thisTest" select="." />
  <xsl:variable name="classId" select="substring-before(., '::')" />

  <Class id="{$classId}">
    <xsl:apply-templates select="//Test[substring-before(., '::') = $classId]" mode="asMethod"/>
  </Class>
</xsl:template>


<xsl:template match="Tests">
  <TestClasses>
    <xsl:apply-templates select="Test[generate-id(.) = generate-id(key('testClassKey', substring-before(., '::'))[1])]" />
  </TestClasses>
</xsl:template>
</xsl:stylesheet>

要获得此结果：

<?xml version="1.0" encoding="UTF-8"?>
<TestClasses>
  <Class id="TestA">
    <Method id="test1" />
    <Method id="test2" />
  </Class>
  <Class id="TestB">
    <Method id="test3" />
    <Method id="test4" />
  </Class>
</TestClasses>

XSLT：拆分和合并XML元素

2 个答案: