Question

我有一个传入的肥皂消息，其形式是TStream（Delphi7），发送此肥皂的服务器处于开发模式，并为消息添加一个html标头以进行调试。现在我需要从它中删除html标题部分才能将其传递给soap转换器。它从“pre”标签开始，以“/ pre”标签结束。我认为它应该相当容易，但我之前在Delphi7中没有这样做过，所以有人可以帮助我吗？

Answer 1

另一个解决方案，更符合Lars的建议，并且不知何故更加成功它的速度更快，特别是当Stream的大小超过100时，甚至更大的那些。它避免复制到中间字符串 FilterBeginStream 更简单，并且在删除标题结尾之前遵循“规范”。
FilterMiddleStream 与DepreStream一样，留下标题前后的内容。

警告：此代码适用于Delphi D2007，而不是D2009。

// returns position of a string token (its 1st char) into a Stream. 0 if not found
function StreamPos(Token: string; AStream: TStream): Int64;
var
  TokenLength: Integer;
  StringToMatch: string;
begin
  Result := 0;
  TokenLength := Length(Token);
  if TokenLength > 0 then
  begin
    SetLength(StringToMatch, TokenLength);
    while AStream.Read(StringToMatch[1], 1) > 0 do
    begin
      if (StringToMatch[1] = Token[1]) and
         ((TokenLength = 1) or
          ((AStream.Read(StringToMatch[2], Length(Token)-1) = Length(Token)-1) and
           (Token = StringToMatch))) then
      begin
        Result := AStream.Seek(0, soCurrent) - (Length(Token) - 1); // i.e. AStream.Position - (Length(Token) - 1);
        Break;
      end;
    end;
  end;
end;

// Returns portion of a stream after the end of a tag delimited header. Works for 1st header.
// Everything preceding the header is removed too. Returns same stream if no valid header detected.
// Result is True if valid header found and stream has been filtered.
function FilterBeginStream(const AStartTag, AEndTag: string; const AStreamIn, AStreamOut: TStream): Boolean;
begin
  AStreamIn.Seek(0, soBeginning); // i.e. AStreamIn.Position := 0;
  Result := (StreamPos(AStartTag, TStream(AStreamIn)) > 0) and (StreamPos(AEndTag, AStreamIn) > 0);
  if Result then
    AStreamOut.CopyFrom(AStreamIn, AStreamIn.Size - AStreamIn.Position)
  else
    AStreamOut.CopyFrom(AStreamIn, 0);
end;

// Returns a stream after removal of a tag delimited portion. Works for 1st encountered tag.
// Returns same stream if no valid tag detected.
// Result is True if valid tag found and stream has been filtered.
function FilterMiddleStream(const AStartTag, AEndTag: string; const AStreamIn, AStreamOut: TStream): Boolean;
var
  StartPos, EndPos: Int64;
begin
  Result := False;
  AStreamIn.Seek(0, soBeginning); // i.e. AStreamIn.Position := 0;
  StartPos := StreamPos(AStartTag, TStream(AStreamIn));
  if StartPos > 0 then
  begin
    EndPos := StreamPos(AEndTag, AStreamIn);
    Result := EndPos > 0;
  end;
  if Result then
  begin
    if StartPos > 1 then
    begin
      AStreamIn.Seek(0, soBeginning); // i.e. AStreamIn.Position := 0;
      AStreamOut.CopyFrom(AStreamIn, StartPos - 1);
      AStreamIn.Seek(EndPos - StartPos + Length(AEndTag), soCurrent);
    end;
    AStreamOut.CopyFrom(AStreamIn, AStreamIn.Size - AStreamIn.Position);
  end
  else
    AStreamOut.CopyFrom(AStreamIn, 0);
end;

Answer 2

创建一个新的TStream（使用TMemoryStream）并使用TStream.CopyFrom或TStream.ReadBuffer / WriteBuffer方法将您想要保留的任何内容从一个流移动到另一个流。

Answer 3

我认为以下代码可以满足您的需求，假设您只有一个＆lt; pre＆gt;阻止你的文件。

function DepreStream(Stm : tStream):tStream;
var
  sTemp : String;
  oStrStm : tStringStream;
  i : integer;
begin
  oStrStm := tStringStream.create('');
  try
    Stm.Seek(0,soFromBeginning);
    oStrStm.copyfrom(Stm,Stm.Size);
    sTemp := oStrStm.DataString;
    if (Pos('<pre>',sTemp) > 0) and (Pos('</pre>',sTemp) > 0) then
      begin
        delete(sTemp,Pos('<pre>',sTemp),(Pos('</pre>',sTemp)-Pos('<pre>',sTemp))+6);
        oStrStm.free;
        oStrStm := tStringStream.Create(sTemp);
      end;
    Result := tMemoryStream.create;
    oStrStm.Seek(0,soFromBeginning);
    Result.CopyFrom(oStrStm,oStrStm.Size);
    Result.Seek(0,soFromBeginning);
  finally
    oStrStm.free;
  end;
end;

我认为另一种选择是使用xml转换来删除不需要的标签，但我对变换的方式做的不多，所以如果有其他人想要那个火炬......

编辑：更正了代码以使其正常工作。教我直接编写SO而不是IDE。

Answer 4

XPath表达式“//pre[1][1]”将拖出第一个＆lt; pre＆gt;的第一个节点。 XML消息中的标记：从您的描述中，应该包含您想要的SOAP消息。

我上次使用它已经很多年了，但我认为Dieter Koehler的OpenXML library支持XPath。

如何在Delphi7中从流中删除一个部分

4 个答案: