Question

当我尝试使用以下Cython代码时，我得到了我在最后发布的关于operator()未定义的错误。看来，当我尝试使用运算符时，Cython不会将其解释为成员函数（请注意，C ++源代码中没有成员访问权限）。如果我尝试拨打prng.operator()()，那么Cython将无法翻译。

在Cython中使用运算符重载需要特殊的东西吗？

import numpy as np
cimport numpy as np

cdef extern from "ratchet.hpp" namespace "ratchet::detail":
    cdef cppclass Ratchet:
        Ratchet()
        unsigned long get64()

cdef extern from "float.hpp" namespace "prng":
    cdef cppclass FloatPRNG[T]:
        double operator()()



cdef FloatPRNG[Ratchet] prng

def ratchet_arr(np.ndarray[np.float64_t, ndim=1] A):
    cdef unsigned int i
    for i in range(len(A)):
        A[i] = prng()


def ratchet_arr(np.ndarray[np.float64_t, ndim=2] A):
    cdef unsigned int i, j
    for i in range(len(A)):
        for j in range(len(A[0])):
            A[i][j] = prng()

ratchet.cpp: In function ‘PyObject* __pyx_pf_7ratchet_ratchet_arr(PyObject*, PyArrayObject*)’: ratchet.cpp:1343:162: error: ‘operator()’ not defined *__Pyx_BufPtrStrided1d(__pyx_t_5numpy_float64_t *, __pyx_pybuffernd_A.rcbuffer->pybuffer.buf, __pyx_t_3, __pyx_pybuffernd_A.diminfo[0].strides) = operator()();

Ianh启发的更多信息。当对象被分配堆栈时，似乎无法使用operator()

cat thing.pyx
cdef extern from 'thing.hpp':
    cdef cppclass Thing:
        Thing(int)
        Thing()
        int operator()()

# When this function doesn't exist, thing.so compiles fine
cpdef ff():
    cdef Thing t
    return t()

cpdef gg(x=None):
    cdef Thing* t
    if x:
        t = new Thing(x)
    else:
        t = new Thing()
    try:
        return t[0]()
    finally:
        del t

cat thing.hpp
#pragma once

class Thing {
    int val;

    public:
    Thing(int v): val(v) {}
    Thing() : val(4) {}

    int operator()() { return val; }
};

Answer 1

更新：从Cython 0.24及更高版本开始，这应该是固定的。我已经在这里完成了解决方法。

在查看C ++编译器之类的示例错误之后，看起来正在发生的事情是Cython在为堆栈分配的对象重载operator()时有一个错误。它似乎试图调用operator()，就好像它是你定义的某种函数而不是你定义的C ++对象的方法。有两种可能的解决方法。您可以为调用运算符设置别名，并在Cython中为其赋予与C中不同的名称。您也可以只在堆上分配对象。

根据您的使用情况，仅修补Cython生成的C文件可能是个好主意。您基本上只需要搜索挂起的operator()调用，将它们更改为适当的C ++对象上的方法调用。我尝试使用下面的示例并且它有效，并且跟踪我需要插入到代码中的对象并不是非常困难。如果您只是尝试将Python绑定编写到库中并且不会在Cython级别对operator()进行大量调用，那么这种方法将很有效，但如果您有一个大的调用，它可能会变得非常痛苦你打算在Cython中做的发展量。

您也可以尝试错误报告。无论你采取哪种方式让它发挥作用，这都会很好。这似乎应该很容易解决，但我不是Cython的内部专家。

这是一个如何在Cython中使用operator()作为堆分配对象的最小工作示例。它适用于Cython 0.21。

Thing.hpp

#pragma once

class Thing{
    public:
        int val;
        Thing(int);
        int operator()(int);};

Thing.cpp

#include "Thing.hpp"

Thing::Thing(int val){
    this->val = val;}

int Thing::operator()(int num){
    return this->val + num;}

Thing.pxd

cdef extern from "Thing.hpp":
    cdef cppclass Thing:
        Thing(int val) nogil
        int operator()(int num) nogil

test_thing.pyx

from Thing cimport Thing

cpdef test_thing(int val, int num):
    cdef Thing* t = new Thing(val)
    print "initialized thing"
    print "called thing."
    print "value was: ", t[0](num)
    del t
    print "deleted thing"

setup.py

from distutils.core import setup
from distutils.extension import Extension
from Cython.Distutils import build_ext
from os import system

# First compile an object file containing the Thing class.
system('g++ -c Thing.cpp -o Thing.o')

ext_modules = [Extension('test_thing',
                         sources=['test_thing.pyx'],
                         language='c++',
                         extra_link_args=['Thing.o'])]

# Build the extension.
setup(name = 'cname',
      packages = ['cname'],
      cmdclass = {'build_ext': build_ext},
      ext_modules = ext_modules)

运行安装文件后，我在同一目录中启动Python解释器并运行

from test_thing import test_thing
test_thing(1, 2)

并打印输出

initialized thing
called thing.
value was:  3
deleted thing

显示操作员正常工作。

现在，如果你想为堆栈分配的对象执行此操作，可以按如下方式更改Cython接口：

Thing.pxd

cdef extern from "Thing.hpp":
    cdef cppclass Thing:
        Thing(int val) nogil
        int call "operator()"(int num) nogil

test_thing.pyx

from Thing cimport Thing

cpdef test_thing(int val, int num):
    cdef Thing t = Thing(val)
    print "initialized thing"
    print "called thing."
    print "value was: ", t.call(num)
    print "thing is deleted when it goes out of scope."

C ++文件和安装文件仍可按原样使用。

Cython不能使用operator（）

1 个答案: