Question

我的vbscript代码遇到了问题。我的HTML代码看起来像这样

<input type='checkbox' name='DisplayRow' id='DisplayRow1' />
<input type='checkbox' name='DisplayRow' id='DisplayRow2' />
<input type='checkbox' name='DisplayRow' id='DisplayRow3' />

这样做是因为上面还有另一个复选框，它调用一个javascript函数来检查或取消选中所有“DisplayRow”复选框。 javascript函数使用getElementsByName返回名为“DisplayRow”的所有复选框。

当单击表单的提交按钮时，操作会将其发送到ASP页面（经典ASP），该页面使用Request.Form命令获取调用表单上的所有对象。 Request.Form命令查看“name”属性，而不是对象的“id”属性。

这似乎适用于所有其他表单对象。当它到达复选框时，因为“name”属性对所有复选框使用相同的名称，它返回一个数组。可以像这样访问各个复选框：

Request.Form("DisplayRow")(x)

其中x引用数组中的单个复选框。

如果选中了复选框，我可以毫无问题地遍历数组。如果未选中一个或多个或所有复选框，则当代码引用未选中的数组中的第一个复选框时，页面将崩溃。 Request.Form命令失败后无法执行任何操作。

我已尝试在If语句的IsNull函数中包含Request.Form（“DisplayRow”）（x），但它仍然会关闭程序。

有没有其他人遇到这个并找到了解决方法？

修改

由于某种原因，stackoverflow不允许我添加多条评论。

@Cory。感谢您提供的信息

@ jwatts1980。计数有效，但它不会让我知道检查了哪个复选框。如果计数大于0，我可以遍历它们，但如果第一个未经检查，我就会回到我开始崩溃页面的地方。

Answer 1

你不能这样做，因为在帖子中不会提交未选中的复选框，只会检查已选中的复选框。

我会采用不同的方法：

首先，我会在复选框中添加value属性，如下所示：

<input type='checkbox' name='DisplayRow' id='DisplayRow1' value="1" />
<input type='checkbox' name='DisplayRow' id='DisplayRow2' value="2" />
<input type='checkbox' name='DisplayRow' id='DisplayRow3' value="3" />

请注意，该值与索引相同，代码中将需要此值。

接下来，我将使用.Split()来收集在数组中选中的复选框，因为值将以逗号分隔的字符串形式出现，即：1,2,3到.Form()值。

Rows = Request.Form("DisplayRow")

'check if any are selected first
If Rows <> "" Then 

  'make an array with each value selected
  aRows = Split(Rows,",")

  'loop through your array and do what you want
  For i = lBound(aRows) to uBound(aRows)
    Response.Write "DisplayRow" & aRows(i) & " was Selected."
  Next

End If

这样您只会处理所选结果，并忽略其他结果。

Answer 2

我一直认为这对我的图书馆至关重要......

'GetPostData
'   Obtains the specified data item from the previous form get or post.
'Usage:
'   thisData = GetPostData("itemName", "Alternative Value")
'Parameters:
'   dataItem (string) - The data item name that is required.
'   nullValue (variant) - What should be returned if there is no value.
'Description:
'   This function will obtain the form data irrespective of type (i.e. whether it's a post or a get).
'Revision info:
'   v0.1.2 -    Inherent bug caused empty values not to be recognised.
'   v0.1.1 -    Converted the dataItem to a string just in case.
function GetPostData(dataItem, nullVal)
    dim rV
    'Check the form object to see if it contains any data...
    if request.Form = "" then
        if request.QueryString = "" then
            rV = nullVal
        else
            if request.QueryString(CStr(dataItem))="" then 
                rV = CStr(nullVal)
            else
                rV = request.QueryString(CStr(dataItem))
            end if
        end if
    else
        if request.Form(CStr(dataItem)) = "" then
            rV = CStr(nullVal)
        else
            rV = request.Form(CStr(dataItem))
        end if
    end if
    'Return the value...
    GetPostData = rV
end function

要使用该功能，您只需传入您正在寻找的表单或查询字符串项以及用...替换空值的内容。

Dim x
x = GetPostData("chkFirstOne", false)

Answer 3

您可以通过添加单个条件继续使用现有代码：

If Request.Form("DisplayRow").Count > 0 Then
    'your code here
Else  
    'consider adding message saying nothing was selected
End If

使用vbscript引用未选中的复选框会导致错误

3 个答案: