Question

我正在尝试设置一个布尔变量。如果键中的至少一个条目与条件匹配，则该变量应该等于true。否则，它应该是假的。假设起始XML是：

<Test>
  <TestEntry exNum="111" exValue="99"/>
  <TestEntry exNum="222" exValue="99"/>
  <TestEntry exNum="111" exValue="101"/>
  <TestEntry exNum="222" exValue="99"/>
  <TestEntry exNum="111" exValue="99"/>
</Test>

然后考虑我尝试的以下方法，考虑exValue是高于还是低于100：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

  <xsl:param name="PARAM">111</xsl:param>
  <xsl:param name="THRESHOLD">100</xsl:param>

  <xsl:key name="exKey" match="/Test/TestEntry" use="@exNum"/>

  <xsl:template name="exampleVariable">
    <xsl:param name="exParam"/>
    <xsl:param name="exThreshold"/>

      <xsl:variable name="exVar" select="key('exKey', $exParam)/@exValue &gt; $exThreshold" />
      <xsl:value-of select="$exVar"/>
  </xsl:template>

  <xsl:template match="/">
    <xsl:call-template name="exampleVariable">
        <xsl:with-param name="exParam" select="$PARAM" />
        <xsl:with-param name="exThreshold" select="$THRESHOLD" />
    </xsl:call-template>
  </xsl:template>

</xsl:stylesheet>

如果$ exParam =＆＃34; 111＆＃34;，我希望$ exVar =＆＃34; true＆＃34;。如果$ exParam！=＆＃34; 111＆＃34;，我希望$ exVar =＆＃34; false＆＃34;。

但是测试永远不会通过，变量总是为false。你对我做错了什么有什么想法吗？

谢谢，马特

Answer 1

当我这样尝试时，它工作正常：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:key name="exKey" match="/Test/TestEntry" use="./@exNum"/>

  <xsl:template name="exampleVariable">
    <xsl:param name="exParam"/>

    <xsl:variable name="exVar">
      <xsl:choose>
        <xsl:when test="key('exKey', $exParam)[@exValue &gt; 100]">
          <xsl:value-of select="'true'"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="'false'"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <xsl:value-of select="$exVar"/>
  </xsl:template>

  <xsl:template match="/">
    <xsl:call-template name="exampleVariable">
      <xsl:with-param name="exParam" select="111" />
    </xsl:call-template>
  </xsl:template>
</xsl:stylesheet>

某个地方一定有问题，你没有向我们展示。请修改您的问题，并提供一个 完整的 示例来重现该问题。

另请注意，您可以极大地简化定义exVar的方式，并将其从10行减少到1行：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

  <xsl:key name="exKey" match="/Test/TestEntry" use="@exNum"/>

  <xsl:template name="exampleVariable">
    <xsl:param name="exParam"/>

    <xsl:variable name="exVar" select="key('exKey', $exParam)/@exValue &gt; 100" />
    <xsl:value-of select="$exVar"/>
  </xsl:template>

  <xsl:template match="/">
    <xsl:call-template name="exampleVariable">
      <xsl:with-param name="exParam" select="111" />
    </xsl:call-template>
  </xsl:template>
</xsl:stylesheet>

这是一种不使用密钥的替代方法。它可能不如关键方法那么有效，但它应该在大多数情况下完成工作：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

  <xsl:variable name="Entries" select="/Test/TestEntry" />    

  <xsl:template name="exampleVariable">
    <xsl:param name="exParam"/>

    <xsl:variable name="exVar" select="$Entries[@exNum = $exParam]/@exValue &gt; 100" />
    <xsl:value-of select="$exVar"/>
  </xsl:template>

  <xsl:template match="/">
    <xsl:call-template name="exampleVariable">
      <xsl:with-param name="exParam" select="111" />
    </xsl:call-template>
  </xsl:template>
</xsl:stylesheet>

Answer 2

甚至更简单：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:key name="exKey" match="TestEntry" use="@exNum"/>

<xsl:param name="exParam" select="111" />
<xsl:variable name="exVar" select="key('exKey', $exParam)/@exValue &gt; 100" />

<xsl:template match="/">
    <xsl:value-of select="$exVar" />
</xsl:template>

</xsl:stylesheet>

XSLT条件密钥测试

2 个答案: