从超类访问__DATA__

Question

我有一个名为Response的超类：

package Response;

use strict;
use warnings;

use HTML::Template;

sub response {
    my ( $class, $request ) = @_;
    return $request->new_response( $class->status, $class->headers, $class->body );
}

sub body {
    my $class = shift;
    my $template = HTML::Template->new( 'filehandle' => eval("$class::DATA") );
    return $template->output() . $class;
}

sub status {
    return 200;
}

sub headers {
    return [ 'Content-Type' => 'text/html' ];
}

1;

__DATA__
Default content

和一个名为URIError的子类：

package URIError;

use strict;
use warnings;

use Response;
our @ISA = qw(Response);

1;

__DATA__
Invalid URI

当调用URIError-＆gt;响应时，行

my $template = HTML::Template->new( 'filehandle' => eval("$class::DATA") );

Response类中的

不会从URIError类中获取 DATA 部分内容。

实现此目的的语法是什么？

Answer 1

如果您更改此类body方法，您的代码将有效。不需要eval：您只需禁用strict 'refs'并取消引用字符串"${class}::DATA"

sub body {
   my $class = shift;

   my $data_fh = do {
      no strict 'refs';
      *{"${class}::DATA"};
   };

   my $template = HTML::Template->new( filehandle => $data_fh );

   $template->output . $class;
}