通过列表框请求从.txt中读取文本

Question

我想做这样的事情

示例：像planer这样的东西我写了特定日子我需要做的事情，当我在列表框当天选择它时，它显示了我需要做的事情。

因为它会记住数据需要保存在某种.txt或数据库上。

我可以像这样添加/加载列表框中的项目

 Private Sub Command1_Click()
      Open "Listbox.txt" For Output As #1
          For i = 0 To list1.ListCount - 1
          Print #1, list1.List(i)
      Next
      Close
End Sub

Private Sub Form_Load()
    list1.AddItem "Monday"
    list1.AddItem "Tuesday"
    list1.AddItem "Wednesday"
    list1.AddItem "Thursday"
    list1.AddItem "Friday"
    list1.AddItem "Saturday"
    list1.AddItem "Sunday"
    End Sub

但主要问题是文本保存。如何在特定日期保存文本框中的文本或进行编辑。因此，当我点击星期一时，它会显示我为星期一输入的自定义文本。

我是否需要在一周内为每天制作一个新文件，例如7个文件或者有更简单的方法？

Answer 1

没有必要为每个列表框项目创建单独的文件。

这是我的示例项目;我对您的表单布局进行了一些更改：

在左侧列表中单击某个项目时，文本字段将提供与该项目关联的文本。通过在/更改相同字段中输入内容来更新项目。

Option Explicit

Private FileStr As String, StrArr() As String

Private Sub cmdSave_Click()

    Dim I As Long
    Open FileStr For Output As #1
    For I = 0 To lbxItems.ListCount - 1
        Print #1, lbxItems.List(I) & "," & StrArr(I)
    Next I
    Close #1

End Sub

Private Sub cmdUpdate_Click()

    StrArr(lbxItems.ListIndex) = txtDescript

End Sub

Private Sub Form_Load()

    Dim I As Long, J As Long
    Dim TempStr As String
    FileStr = App.Path & "\planner.txt"
    Open FileStr For Input As #1
    Do Until EOF(1)
        Line Input #1, TempStr
        J = InStr(TempStr, ",")
        lbxItems.AddItem Left$(TempStr, J - 1)
        TempStr = Mid$(TempStr, J + 1)
        ReDim Preserve StrArr(I)
        StrArr(I) = TempStr
        I = I + 1
    Loop
    Close #1

End Sub

Private Sub lbxItems_Click()

    txtDescript = StrArr(lbxItems.ListIndex)

End Sub

代码的设计使其可以与插入＆＃34; planner.txt＆＃34;的其他项目一起使用。文件手动。如果这样做，请确保使用逗号（，）跟随项目名称。

如果您将代码直接复制并粘贴到表单代码模块中，请确保根据需要更新控件名称。