Question

在Excel中，我尝试根据当前年份创建自动编号单元格，并按顺序创建下一个数字。表14/001中的第一行示例，下一行应为14/002 ...

我已将表单格式化为表格，而我在公式=TEXT(TODAY(),"yy")& "/" &TEXT(ROW(A1),"000")中的公式为A2。

当我选中表格中的行，并到达行的最后一个单元格时，它默认为下一行，创建一个新行，并将公式复制下来，并按预期增加一。那部分工作得很好。

我不知道怎么做的是当这些年到2015年时，如何重置/00？到/001所以2015年1月1日，下一行应为15/001

Answer 1

    =TEXT(TODAY(),"yy")& "/" &
                    if(left(previous_cell,2)=TEXT(TODAY(),"yy"),
                       TEXT(ROW(A1),"000"),
                       "001")

Answer 2

由于您愿意接受VBA解决方案，因此假定自动编号将位于 A 列中。手动将第一个值放在 A1 中。然后在工作表代码区域中输入以下事件宏：

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Dim A As Range, oldYr As String, yr As String, N As Long, oldN As Long
    Set A = Range("A2:A" & Rows.Count)
    If Intersect(Target, A) Is Nothing Then Exit Sub
    If Target.Value <> "" Or Target.Offset(-1, 0) = "" Then Exit Sub
    Cancel = True
    ary = Split(Target.Offset(-1, 0).Value, "/")
    oldYr = ary(0)
    oldN = CLng(ary(1))
    yr = Right(CStr(Year(Date)), 2)
    If yr = oldYr Then
        Target.Value = yr & "/" & Format(oldN + 1, "000")
    Else
        Target.Value = yr & "/" & Format(1, "000")
    End If
End Sub

如果您双击 A 列中的第一个空单元格，则会在该单元格中输入下一个自动编号。

因为它是工作表代码，所以很容易安装和自动使用：

右键单击Excel窗口底部附近的选项卡名称
选择查看代码 - 这会打开一个VBE窗口
粘贴内容并关闭VBE窗口

如果您有任何疑虑，请先在试用工作表上试用。

如果保存工作簿，宏将随之保存。如果您在2003年之后使用的是Excel版本，则必须保存该文件为.xlsm而不是.xlsx

删除宏：

按上述方式调出VBE窗口
清除代码
关闭VBE窗口

要了解有关宏的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/getstarted.htm

和

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

要了解有关事件宏（工作表代码）的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/event.htm

必须启用宏才能使其生效！

自动编号重置

2 个答案: