Question

说我有以下xml结构：

<a>
    <t id="27"></t>
    <t id="23"></t>
    <b id="a"></b>
    <b id="t"></b>
    <b id="p"></b>
    <c id="er"></c>
</a>

我想创建一个新的xml文件，只有b标签按属性id排序，并保持文件的其余部分不变：

<a>
    <t id="27"></t>
    <t id="23"></t>
    <b id="a"></b>
    <b id="p"></b>
    <b id="t"></b>
    <c id="er"></c>
</a>

我该怎么做？

这是我在帖子中找到的：

<xsl:stylesheet version="2.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xs="http://www.w3.org/2001/XMLSchema">
  <xsl:output method="xml" encoding="UTF-8" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:choose>
        <xsl:when test="*[local-name()='MEASV']">
          <xsl:apply-templates select="@* | node()">
            <xsl:sort select="@id" />
          </xsl:apply-templates>
        </xsl:when>
        <xsl:otherwise>
          <xsl:apply-templates select="@* | node()" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

但它不适用于此示例：

<a>
    <b id="7"></b>
    <b id="2"></b>
    <b id="5"></b>
    <b id="9"></b>
    <MEASV id="7"></MEASV>
    <MEASV id="10"></MEASV>
    <MEASV id="6"></MEASV>
    <MEASV id="3"></MEASV>
    <MEASV id="5"></MEASV>
</a>

，并提供：

<?xml version="1.0" encoding="UTF-8"?>
<a>
<MEASV id="10"></MEASV>
<b id="2"></b>
<MEASV id="3"></MEASV>
<b id="5"></b>
<MEASV id="5"></MEASV>
<MEASV id="6"></MEASV>
<b id="7"></b>
<MEASV id="7"></MEASV>
<b id="9"></b>
</a>

请帮忙吗？

Answer 1

也许你可以使用这样的东西：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

 <xsl:template match="a">
    <xsl:copy>
        <xsl:apply-templates select="*">
            <xsl:sort select="name()"/>
            <xsl:sort select="@id[parent::b]"/>
        </xsl:apply-templates>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

导致：

<?xml version="1.0" encoding="UTF-8"?>
<a>
   <b id="a"/>
   <b id="p"/>
   <b id="t"/>
   <c id="er"/>
   <t id="27"/>
   <t id="23"/>
</a>

为您的第一个示例，并且：

<?xml version="1.0" encoding="UTF-8"?>
<a>
   <b id="2"/>
   <b id="5"/>
   <b id="7"/>
   <b id="9"/>
   <MEASV id="7"/>
   <MEASV id="10"/>
   <MEASV id="6"/>
   <MEASV id="3"/>
   <MEASV id="5"/>
</a>

为第二个。

请注意，对于文本和数字，排序是不同的，因此一种类型不能真正适合您的两个示例。

Answer 2

假设XSLT 2.0是可能的，因为它被用于提供的例子中。

以下内容将保留基本结构，并仅对相邻的b＆＃39; s进行排序：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 exclude-result-prefixes="xs"
xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:output method="xml" encoding="UTF-8" indent="yes"/>

<xsl:template match="a">
    <xsl:copy>
        <!-- group any adjacent b's together -->
        <xsl:for-each-group select="*" group-adjacent="local-name()='b'">
            <xsl:choose>
                <!-- if b sort by id -->
                <xsl:when test="current-grouping-key()">
                    <xsl:apply-templates select="current-group()">
                        <xsl:sort select="@id" data-type="number"/>
                    </xsl:apply-templates>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:apply-templates select="current-group()"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each-group>
    </xsl:copy>
</xsl:template>

<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

这将为第一个例子产生以下内容：

<a>
  <t id="27"/>
  <t id="23"/>
  <b id="a"/>
  <b id="t"/>
  <b id="p"/>
  <c id="er"/>
</a>

这是第二次：

<a>
   <b id="2"/>
   <b id="5"/>
   <b id="7"/>
   <b id="9"/>
   <MEASV id="7"/>
   <MEASV id="10"/>
   <MEASV id="6"/>
   <MEASV id="3"/>
   <MEASV id="5"/>
</a>

按属性值对特定xml标记进行排序

2 个答案: