Question

我正在尝试从其中一个Windows虚拟文件夹（例如，相机或iPhone图片文件夹）加载文件的内容。下面是我用来解决的一些示例代码：

procedure TfrmForm.ButtonClick(Sender: TObject);
Var
  Dialog: TAttachDialog;
  Enum: IEnumShellItems;
  Name: LPWSTR;
  Item: IShellItem;
  Strm: IStream;
  OStrm: TOLEStream;
  FStrm: TFileStream;
  Result: HRESULT;
  Buf: Array[0..99] Of Char;
  Read: LongInt;
begin
  Result := CoInitializeEx(Nil, COINIT_APARTMENTTHREADED Or
                                COINIT_DISABLE_OLE1DDE);
  If Succeeded(Result) Then
  Begin
    Dialog := TAttachDialog.Create(Self);
    Try
      Dialog.Options := [fdoAllowMultiSelect, fdoPathMustExist,
                         fdoFileMustExist];
      Dialog.Title := 'Select Attachments';

      If Dialog.Execute(Self.Handle) Then
      Begin
        If FAILED(Dialog.ShellItems.EnumItems(Enum)) Then
          Raise Exception.Create('Could not get the list of files selected.');

        While Enum.Next(1, Item, Nil) = S_OK Do
        Begin
          If (Item.GetDisplayName(SIGDN_NORMALDISPLAY, Name) = S_OK) Then
          Begin
            mResults.Lines.Add(Name);
            CoTaskMemFree(Name);
          End;

          If Item.BindToHandler(Nil, BHID_Stream, IID_IStream, Strm) = S_OK Then
          Begin
            OStrm := TOLEStream.Create(Strm);
            FStrm := TFileStream.Create('C:\Temp\Test.jpg', fmCreate);
            FStrm.CopyFrom(OStrm, OStrm.Size);
            FreeAndNil(OStrm);
            FreeAndNil(FStrm);
            Strm := Nil;
          End;

          Item := Nil;
        End;
      End;
    Finally
      FreeAndNil(Dialog);
    End;
    CoUninitialize;
  End;
end;

TAttachDialog只是TCustomFileOpenDialog的后代，它暴露了ShellItems属性。在我的实际应用程序中，我需要返回一个TStream对象。所以，在这个例子中，我使用TFileStream顶部复制源文件作为概念证明，我已经使用Delphi流成功访问了该文件。一切正常，直到我尝试FStrm.CopyFrom，此时我得到一个＆＃34; Not Implemented＆＃34;错误。我做错了什么，或者有更好的办法完全做我想做的事情？

Answer 1

唯一一次TStream本身会引发＆＃34;未实施＆＃34;如果Seek()的32位或64位版本都没有在后代类（或其中一个错误地称为inherited方法）中被覆盖，则会出现错误。如果这是真的，则会引发EStreamError异常，说＆＃34; ClassName.Seek未实现＆＃34;。

TOLEStream会覆盖32位版本的Seek()来调用IStream.Seek()。但是，它不会覆盖TStream.GetSize()属性getter。因此，当您在调用OStrm.Size之前阅读CopyFrom()值时，会调用默认的TStream.GetSize()方法，该方法使用Seek()来确定流大小 - Seek()为获取当前位置，然后再次Seek()到流的末尾，保存结果，然后再次Seek()返回上一个位置。

所以，我的猜测是你获得的IStream可能不支持随机搜索，因此Seek()方法返回E_NOTIMPL，TOLEStream.Seek()会检测到提出EOleSysError例外说＆＃34;未实施＆＃34;。

尝试调用IStream.Stat()以获取流大小（或从TOLEStream派生类并覆盖GetSize()方法以调用Stat()），然后传递返回的大小如果＆gt;到CopyFrom() 0（如果您将Count=0传递给CopyFrom()，它将会读取源流的Position和Size属性，从而导致相同的Seek()错误），例如：

var
  ...
  Stat: STATSTG;
begin
  ...
  if Item.BindToHandler(Nil, BHID_Stream, IID_IStream, Strm) = S_OK Then
  try
    OStrm := TOLEStream.Create(Strm);
    try
      FStrm := TFileStream.Create('C:\Temp\Test.jpg', fmCreate);
      try
        OleCheck(Strm.Stat(Stat, STATFLAG_NONAME));
        if Stat.cbSize.QuadPart > 0 then
          FStrm.CopyFrom(OStrm, Stat.cbSize.QuadPart);
      finally
        FreeAndNil(FStrm);
      end;
    finally
      FreeAndNil(OStrm);
    end;
  finally
    Strm := Nil;
  end;
  ...
end;

另一种方法是简单地避免TStream.CopyFrom()并自己手动复制字节，方法是分配一个本地缓冲区，然后在循环中调用OStrm.Read()，将每个读缓冲区写入FStrm，直到OStrm.Read()报告没有更多字节要读：

var
  ...
  Buf: array[0..1023] of Byte;
  NumRead: Integer;
begin
  ...
  if Item.BindToHandler(Nil, BHID_Stream, IID_IStream, Strm) = S_OK Then
  try
    OStrm := TOLEStream.Create(Strm);
    try
      FStrm := TFileStream.Create('C:\Temp\Test.jpg', fmCreate);
      try
        repeat
          NumRead := OStrm.Read(Buf[0], SizeOf(Buf));
          if NumRead <= 0 then Break;
          FStrm.WriteBuffer(Buf[0], NumRead);
        until False;
      finally
        FreeAndNil(FStrm);
      end;
    finally
      FreeAndNil(OStrm);
    end;
  finally
    Strm := Nil;
  end;
  ...
end;

使用Delphi 2007从虚拟文件夹加载文件

1 个答案: