Question

我正在尝试运行批处理脚本来获取CPU，RAM和活动网卡等基本计算机信息。这是我的代码

@Echo OFF

set newline=^& echo.

echo Manufacturer Information> test1.txt

systeminfo|findstr /c:"Host Name" /c:"OS Name" /c:"System Model:" /c:"System Type:" /c:"Total Physical Memory:" >>test1.txt

echo CPU Information:>> test1.txt

wmic cpu get Name /Format:list >> test1.txt

echo %newline%Process Information:>> test1.txt

wmic computersystem get NumberofProcessors /Format:list >> test1.txt

echo %newline%NIC Information:>> test1.txt

wmic nicconfig where "IPEnabled=TRUE" get ipaddress, macaddress,defaultipgateway /format:list >>test1.txt

输出看起来：

制造商信息主机名称：DK-IT OS名称：
  Microsoft Windows 8.1单语言系统模型：
  Inspiron 7537系统类型：基于x64的PC总物理   内存：6,043 MB CPU信息：
 N a m e = I n t e l ( R )   C o r e ( T M )   i 5 - 4 2 0 0 U   C P U   @   1 . 6 0 G H z 



Process Information:


 N u m b e r O f P r o c e s s o r s = 1 



NIC Information:


 D e f a u l t I P G a t e w a y = { " 1 0 . 5 . 1 . 1 " }     I P A d d r e s s = { " 1 0 . 5 . 4 . 5 4 " , " f e 8 0 : : 1 0 e b : 1 d
2 d：2 0 8 8：8 b a 1“} M A C A d d r e s s = 0 C：8 B：F D ：9 C：8 0：4 7
 D e f a u l t I P G a t e w a y =     I P A d d r e s s = { " 1 9 2 . 1 6 8 . 1 9 9 . 1 " }     M A C A d d r e s s = 0 0 : 5 0 : 5 6 :
C 0：0 0：0 1

D e f a u l t I P G a t e w a y = I P A d d r e s s = {“1 9 2   。 1 6 8。 1 9 0。 1“，”f e 8 0 :: 6 4 b 2：2 a a a：e f 6 4：f   a 9 a“} M A C A d d r e s s = 0 0：5 0：5 6：C 0：0 0：0 8

有人可以帮助修改批处理文件输出的视图吗？

Answer 1

您的问题是SYSTEMINFO产生ANSII输出（与大多数命令一样），但WMIC产生Unicode输出。两者混合不好。

以下三种解决方案均可产生ANSII输出。

1）将WMIC输出传输到MORE

更多将Unicode转换为ANSII。我还将结果传递给FINDSTR以消除空行。此解决方案的唯一问题是转换的怪癖会导致WMIC输出在每行末尾有一个额外的回车符（<CR><CR><LF>而不是<CR><LF>）

@echo OFF
>test1.txt (
  echo Manufacturer Information:
  systeminfo|findstr /c:"Host Name" /c:"OS Name" /c:"System Model:" /c:"System Type:" /c:"Total Physical Memory:"

  echo(
  echo CPU Information:
  wmic cpu get Name /Format:list | more | findstr .
  wmic computersystem get NumberofProcessors /Format:list | more | findstr .

  echo(
  echo NIC Information:
  wmic nicconfig where IPEnabled=TRUE get ipaddress, macaddress,defaultipgateway /format:list | more | findstr .
)

------------------------------

其余的解决方案都已正确格式化，没有任何额外的<CR>

2）将WMIC输出写入临时文件，然后输入TYPE

临时文件采用Unicode格式，TYPE正确地将Unicode转换为ANSII。我仍然将结果传递给FINDSTR以消除空行。

@echo OFF
>test2.txt (
  echo Manufacturer Information:
  systeminfo|findstr /c:"Host Name" /c:"OS Name" /c:"System Model:" /c:"System Type:" /c:"Total Physical Memory:"

  echo(
  echo CPU Information:
  call :wmic cpu get Name /Format:list
  call :wmic computersystem get NumberofProcessors /Format:list

  echo(
  echo NIC Information:
  call :wmic nicconfig where IPEnabled=TRUE get ipaddress, macaddress,defaultipgateway /format:list
)
exit /b

:wmic
wmic %* >test.tmp
type test.tmp | findstr .
del test.tmp
exit /b

3）通过两个FOR / F循环运行WMIC。

第一个FOR / F将WMIC输出转换为ANSII，但在每一行的末尾都有额外的<CR>。第二个FOR / F剥离不需要的尾随<CR>。 FOR / F自动剥离空行。

@echo OFF
>test3.txt (
  echo Manufacturer Information:
  systeminfo|findstr /c:"Host Name" /c:"OS Name" /c:"System Model:" /c:"System Type:" /c:"Total Physical Memory:"

  echo(
  echo CPU Information:
  call :wmic cpu get Name /Format:list
  call :wmic computersystem get NumberofProcessors /Format:list

  echo(
  echo NIC Information:
  call :wmic nicconfig where IPEnabled=TRUE get ipaddress, macaddress,defaultipgateway /format:list
)
exit /b

:wmic
for /f "delims=" %%A in ('"wmic %*"') do for /f "delims=" %%B in ("%%A") do echo %%B
exit /b

wmic命令的批处理脚本中的文本乱码

1 个答案: