Question

我正在尝试使用超链接而不是按钮来运行Basic宏。对我来说似乎更自然，因为超链接直接连接到单元格而按钮不是。我正在使用以下公式：

=HYPERLINK("vnd.sun.star.script:Standard.Module1.Test?language=Basic&location=document";"Check")

它应该调用位于 Standard.Module1 下的文档宏中的子例程 Test ，并在它写入的单元格中显示文本'Check'。

这与libreoffice 3.6.1.2完全兼容，但它在版本4.1.4.2中根本不起作用。我看不到任何错误，它根本就没有发生任何事情。我试图只需单击超链接，然后按住CTRL并单击它。相同的结果 - 没有。

当我使用按钮时，宏按预期工作。有谁知道如何解决这个问题？

Answer 1

这似乎是Calc中的一个错误。协议vnd.sun.star.script在仍在版本4.2中的Writer中的超链接URL中运行。但在Calc中却没有。

作为一种解决方法，您可以将以下功能附加到工作表事件＆＃34;双击＆＃34;。如果您使用= HYPERLINK公式双击单元格，则宏将运行。

最后两个版本是我的第一个想法的结果。由于可理解的原因，我会让他们回答。但是在我看来，这最后一个版本是最好的解决方法。最接近的工作就像原始的vnd.sun.star.script：URL。

public function Doubelclicked(target) as Boolean

 if left(target.formula, 32) = "=HYPERLINK(""vnd.sun.star.script:" then
  sFormulaHyperlink = target.formula

  sMacroURLRaw = mid(sFormulaHyperlink, 13, instr(13, sFormulaHyperlink, ";") - 13)
  target.formula = "=""" & sMacroURLRaw 
  sMacroURL = target.string
  target.formula = sFormulaHyperlink

  oDisp = createUnoService("com.sun.star.frame.DispatchHelper")

  dim args(0) as new com.sun.star.beans.PropertyValue
  args(0).Name = "URL"
  args(0).Value = sMacroURL

  oFrame = ThisComponent.CurrentController.Frame
  oDisp.executeDispatch(oFrame, sMacroURL, "", 0, args)
 end if   

 Doubelclicked = false
end function

以下是以前的版本：

public function Doubelclicked(target) as Boolean
 if left(target.formula, 32) = "=HYPERLINK(""vnd.sun.star.script:" then
   sMacroURL = mid(target.formula, 13, instr(13, target.formula, chr(34))-13)
   oDisp = createUnoService("com.sun.star.frame.DispatchHelper")
   oFrame = ThisComponent.CurrentController.Frame
   oDisp.executeDispatch(oFrame, sMacroURL, "", 0, Array())   
 end if
 Doubelclicked = false
end function

使用此功能无法在宏URL中传递参数。但是如果只是获取调用宏的单元格地址的目标，那么这是可能的，因为我们有双击目标。所以我更新了我的解决方法。

public function Doubelclicked(target) as Boolean
 if left(target.formula, 32) = "=HYPERLINK(""vnd.sun.star.script:" then

  lStartLocation = instr(13, target.formula,"&location=")
  if lStartLocation > 0 then
   lEndLocation = instr(lStartLocation + 1, target.formula,"&")
   if lEndLocation = 0 then lEndLocation = instr(lStartLocation + 1, target.formula,"""")

   sMacroURL = mid(target.formula, 13, lEndLocation - 13)
   'msgbox sMacroURL
   oDisp = createUnoService("com.sun.star.frame.DispatchHelper")

   dim args(2) as new com.sun.star.beans.PropertyValue
   args(0).Name = "TargetAddress"
   args(0).Value = target.AbsoluteName

   oFrame = ThisComponent.CurrentController.Frame
   oDisp.executeDispatch(oFrame, sMacroURL, "", 0, args)
  end if   
 end if
 Doubelclicked = false
end function

问候

阿克塞尔

Libreoffice Calc使用HYPERLINK运行宏

1 个答案: