Question

对于你们所有人来说，制作ppt的人幻灯片的动画如下：

逐一展示项目符号
逐个显示图像或缩放图
在活动元素上显示边框
内部导航/菜单/链接到另一张幻灯片
幻灯片之间的转换

是否有工具可以将ppt转换为PDF并将每个动画保存在单独的幻灯片中？例如？

我知道您可以使用 LaTeX Beamer 创建动画幻灯片，可以很好地转换为PDF，我已经制作了一些，但我也有一些我要转换为PDF的ppt文件

这是我到目前为止所尝试的：

Slideshare ，但不仅它不支持动画，而且内部导航不起作用，而且字体都搞砸了。
PDFcreator ，相比之下质量相当优异，但它既不支持动画也不支持动画。作为Slideshare，它只会将一个图像放在另一个上。此外，它不支持透明度（例如，图像上具有半透明bg的文本框）
LaTeX Beamer ，已经提到了，但我更愿意避免将这些ppts内容和动画输入到LaTeX中，以便动画在PDF中正确显示。

我搜索过SO并没有找到满意的答案来处理动画。你用什么？

Answer 1

我找到了一个小插件，可以在动画时分割你的powerpoint幻灯片。因此，如果您在1张幻灯片上有3个动画，他将逐步生成每个动画的3张幻灯片。然后以PDF格式导出： - ）

它在powerpoint 2010上对我有用。我建议你在分割之前做一个演示文稿的备份文件。并且不要忘记取消选中＆＃34;拆分点击触发的动画＆＃34;。

http://www.dia.uniroma3.it/~rimondin/downloads.php

我也发现了这个（但第一个解决方案是免费的，并且工作如下:-)） http://www.verypdf.com/wordpress/201306/how-to-create-a-pdf-from-powerpoint-with-animations-36850.html

Answer 2

这个blog post提供了一个VBA宏脚本，它将每张具有动画的幻灯片（例如逐个出现的图像或项目符号）拆分成多个幻灯片，然后您可以保存为PDF并瞧！

重要的是，由于它是一个VBA脚本，应该适用于Windows和Mac 。我只使用powerpoint 2011在OSX（优胜美地）上试过它，它运行得很好。我唯一的问题是带有动画项目符号的幻灯片（逐个显示）被分成多个幻灯片，但每张幻灯片都包含所有项目符号，所以我不得不手动删除一些。尽管如此，对于其他一切工作都很完美，与手动完成相比，这是一个很小的代价，特别是图像动画。当然，您可能/可能不会在Windows或其他版本的PP上遇到相同的问题。无论如何，OSX的是迄今为止我发现的唯一可行解决方案。

可以找到有关向powerpoint添加VBA宏的说明{。{3}}。

希望它也适合你！

Answer 3

此blog post提供了一个VBA宏脚本，可以将每个包含动画的幻灯片拆分为多个幻灯片，而不会将原始幻灯片保留在展开的幻灯片前面（如this answer中所示）。

此宏和另一个宏保留的问题是，具有多个动画的文本块的内容始终显示为整体（例如，如果同一文本块的每个句子都有单独的动画，则所有句子都将总是一起出现。）

VBA代码：

Private AnimVisibilityTag As String

Sub ExpandAnimations()
AnimVisibilityTag = "AnimationExpandVisibility"

Dim pres As Presentation
Dim Slidenum As Integer

Set pres = ActivePresentation
Slidenum = 1
Do While Slidenum <= pres.Slides.Count
Dim s As Slide
Dim animationCount As Integer
Set s = pres.Slides.Item(Slidenum)

If s.TimeLine.MainSequence.Count > 0 Then
    Set s = pres.Slides.Item(Slidenum)
    PrepareSlideForAnimationExpansion s
    animationCount = expandAnimationsForSlide(pres, s)
Else
    animationCount = 1
End If
Slidenum = Slidenum + animationCount
Loop
End Sub

Private Sub PrepareSlideForAnimationExpansion(s As Slide)
' Set visibility tags on all shapes
For Each oShape In s.Shapes
oShape.Tags.Add AnimVisibilityTag, "true"
Next oShape

' Find initial visibility of each shape
For animIdx = s.TimeLine.MainSequence.Count To 1 Step -1
Dim seq As Effect
Set seq = s.TimeLine.MainSequence.Item(animIdx)
On Error GoTo UnknownEffect
For behaviourIdx = seq.Behaviors.Count To 1 Step -1
    Dim behavior As AnimationBehavior
    Set behavior = seq.Behaviors.Item(behaviourIdx)
    If behavior.Type = msoAnimTypeSet Then
        If behavior.SetEffect.Property = msoAnimVisibility Then
            If behavior.SetEffect.To <> 0 Then
                seq.Shape.Tags.Delete AnimVisibilityTag
                seq.Shape.Tags.Add AnimVisibilityTag, "false"
            Else
                seq.Shape.Tags.Delete AnimVisibilityTag
                seq.Shape.Tags.Add AnimVisibilityTag, "true"
            End If
        End If
    End If
Next behaviourIdx
NextSequence:
On Error GoTo 0
Next animIdx
Exit Sub

UnknownEffect:
MsgBox ("Encountered an error while calculating object visibility: " + Err.Description)
Resume NextSequence
End Sub

Private Function expandAnimationsForSlide(pres As Presentation, s As Slide) As Integer
Dim numSlides As Integer
numSlides = 1

' Play the animation back to determine visibility
Do While True
' Stop when animation is over or we hit a click trigger
If s.TimeLine.MainSequence.Count <= 0 Then Exit Do
Dim fx As Effect
Set fx = s.TimeLine.MainSequence.Item(1)
If fx.Timing.TriggerType = msoAnimTriggerOnPageClick Then Exit Do

' Play the animation
PlayAnimationEffect fx
fx.Delete
Loop

' Make a copy of the slide and recurse
If s.TimeLine.MainSequence.Count > 0 Then
s.TimeLine.MainSequence.Item(1).Timing.TriggerType = msoAnimTriggerWithPrevious
Dim nextSlide As Slide
Set nextSlide = s.Duplicate.Item(1)
numSlides = 1 + expandAnimationsForSlide(pres, nextSlide)
End If

' Apply visibility
rescan = True
While rescan
rescan = False
For n = 1 To s.Shapes.Count
    If s.Shapes.Item(n).Tags.Item(AnimVisibilityTag) = "false" Then
        s.Shapes.Item(n).Delete
        rescan = True
        Exit For
    End If
Next n
Wend

' Clear all tags
For Each oShape In s.Shapes
oShape.Tags.Delete AnimVisibilityTag
Next oShape

' Remove animation (since they've been expanded now)
While s.TimeLine.MainSequence.Count > 0
s.TimeLine.MainSequence.Item(1).Delete
Wend

expandAnimationsForSlide = numSlides
End Function


Private Sub assignColor(ByRef varColor As ColorFormat, valueColor As ColorFormat)
If valueColor.Type = msoColorTypeScheme Then
varColor.SchemeColor = valueColor.SchemeColor
Else
varColor.RGB = valueColor.RGB
End If
End Sub


Private Sub PlayAnimationEffect(fx As Effect)
On Error GoTo UnknownEffect
For n = 1 To fx.Behaviors.Count
Dim behavior As AnimationBehavior
Set behavior = fx.Behaviors.Item(n)
Select Case behavior.Type
    Case msoAnimTypeSet
        ' Appear or disappear
        If behavior.SetEffect.Property = msoAnimVisibility Then
            If behavior.SetEffect.To <> 0 Then
                fx.Shape.Tags.Delete AnimVisibilityTag
                fx.Shape.Tags.Add AnimVisibilityTag, "true"
            Else
                fx.Shape.Tags.Delete AnimVisibilityTag
                fx.Shape.Tags.Add AnimVisibilityTag, "false"
            End If
        Else
            ' Log the problem
        End If
    Case msoAnimTypeColor
        ' Change color
        If fx.Shape.HasTextFrame Then
            Dim range As TextRange
            Set range = fx.Shape.TextFrame.TextRange
            assignColor range.Paragraphs(fx.Paragraph).Font.Color, behavior.ColorEffect.To
        End If


    Case Else
        ' Log the problem
End Select
Next n
Exit Sub
UnknownEffect:
MsgBox ("Encountered an error expanding animations: " + Err.Description)
Exit Sub
End Sub

Answer 4

对于使用LibreOffice或OpenOffice的用户， github上有一个插件可以很好地完成此任务：

ExpandAnimations

根据我的经验，所有标准的出现/消失动画都被很好地分割了。对象移动动画也可以工作（您将获得一张幻灯片，其中包含对象的开始位置，而幻灯片中包含对象的结束位置）。我没有机会测试其他动画类型，但这应该可以满足所有标准需求：-）

动画幻灯片转换为静态PDF

4 个答案: