Question

我们在AI课程中一直使用Lisp。我收到的作业涉及搜索和生成树状结构。对于每个作业，我最终都写了类似的内容：

(defun initial-state ()
  (list 
    0    ; score
    nil  ; children
    0    ; value
    0))  ; something else

并围绕这些“状态”构建我的函数，这些状态实际上只是具有一些松散定义结构的嵌套列表。

为了使结构更加严格，我尝试编写访问器，例如：

(defun state-score ( state )
  (nth 2 state))

这适用于读取值（这应该是我在一个功能良好的世界中需要做的全部。但是，随着时间的推移，我开始疯狂地破解，有时我想要一个可变的结构）。我似乎无法SETF返回...的东西（地点？值？指针？）。

我收到的错误如下：

(setf (state-score *state*) 10)

有时我似乎有更多的运气将accessor / mutator写成宏：

(defmacro state-score ( state )
  `(nth 2 ,state))

但是我不知道为什么这应该是一个宏，所以我当然不应该把它写成一个宏（除了有时候它有效。巧合编程很糟糕）。

建立这样的结构的适当策略是什么？

更重要的是，我在哪里可以了解这里发生的事情（哪些操作以什么方式影响记忆）？

Answer 1

将CLOS用于数据结构

最好的方法是快速学习CLOS的基础知识。

(defclass state ()
  ((score    :accessor state-score    :initform 0)
   (children :accessor state-children :initform nil)
   (value    :accessor state-value    :initform 0)))

(defun make-initial-state ()
  (make-instance 'state))

(defparameter *state* (make-initial-state))

(setf (state-score *state*) 10)

对于大多数应用程序代码避免使用结构

对于大多数代码避免使用结构 - 仅在需要时使用它们并知道原因。改为使用CLOS类。

DEFSTRUCT也适用于列表

如果你真的想使用列表，一个选项是将DEFSTRUCT宏与列表一起使用并让它定义所有函数：

(defstruct (state (:type list))
  (score 0)
  (children nil)
  (value 0))

上面，：type选项告诉DEFSTRUCT使用列表而不是结构。

? (defparameter *state* (make-state))
*STATE*
? (setf (state-score *state*) 10)
10

（make-state）返回三个项目的列表。

我们可以编写setter函数

如果你想手工编写代码，那么你可以编写setter函数：

(defun get-my-score (state)
  (first state))

(defun (setf get-my-score) (score state)
  (setf (first state) score))

上面定义了一个SETF函数。该函数的名称实际上是一个列表。该函数的参数必须首先是新值，然后是要设置的东西。

? (setf *state* (list 0 nil 0))
(0 NIL 0)
? (setf (get-my-score *state*) 10)
10
? *state*
(10 NIL 0)

Common Lisp HyperSpec定义了哪些地方以及如何使用它们。我猜这不是最好的学习资源，可能最好在一些介绍性的Lisp书中解释。

Answer 2

您可以使用以下内容：

(defun get-score (state)
  (nth 0 state)) ; This corresponds to the comments in the init function

(defun set-score (state new-value)
  (setf (nth 0 state) new-value))

(defsetf get-score set-score)

这样，只要您撰写(setf (get-score something) else)，就会将其翻译为(set-score something else)。

Answer 3

使用defstruct：

> (defstruct state score children val something-else)
STATE
> (setq initial-state (make-state :score 0 :children nil :val 0 :something-else nil))
#S(STATE :SCORE 0 :CHILDREN NIL :VAL 0 :SOMETHING-ELSE NIL)
> (state-score initial-state) ; current score
0
> (setf (state-score initial-state) 10) ; set new score
10
> (state-score initial-state) 
10

Answer 4

这是因为setf是一个宏。将state-score定义为宏时，setf会看到：

(setf (nth 2 state) value)

并知道该怎么做，因为它可以使用nth作为地点来存储值。另一方面，当state-score是函数时，setf只会看到返回的值，并且无法对其执行任何操作。

详细了解setf的工作原理及其地方的概念，以便更深入地了解。 Here's一个有趣的教程，说：

setf特殊形式首先使用它在内存中定义一个位置的参数，评估它的第二个参数，和将结果值存储在产生的内存位置

如何通过访问器在树中设置元素？

4 个答案: