Question

让我们说我有字符串

[Apple,Pie,Pizza]

我怎么能把它变成

<Root>
    <Apple/>
    <Pie/>
    <Pizza/>
</Root>

我可以轻松摆脱括号并对字符串进行标记，但它会得到一个数组，我不知道如何转换为元素列表。

由于

Answer 1

XSLT的常规输入必须始终为XML，因此下面的样式表假定为输入：

<?xml version="1.0" encoding="UTF-8"?>
<string>[Apple,Pie,Pizza]</string>

样式表（XSLT 2.0）

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="string">
        <root>
            <xsl:for-each select="tokenize(substring(.,2, string-length()-2),',')">
                <xsl:element name="{.}"/>
            </xsl:for-each>
        </root>
    </xsl:template>

</xsl:stylesheet>

<强>输出

<root>
   <Apple/>
   <Pie/>
   <Pizza/>
</root>

如果您只能使用XSLT 1.0，那么在XSLT 1.0中实现相同的递归模板。

样式表（XSLT 1.0）

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="string">
        <root>
            <xsl:call-template name="elementifier">
                <xsl:with-param name="str" select="substring(.,2, string-length()-2)"/>
            </xsl:call-template>
        </root>
    </xsl:template>

    <xsl:template name="elementifier">
        <xsl:param name="str"/>

        <xsl:choose>
            <xsl:when test="$str">
                <xsl:variable name="element-name">
                    <xsl:choose>
                        <xsl:when test="contains($str,',')">
                            <xsl:value-of select="substring-before($str,',')"/>
                        </xsl:when>
                        <xsl:otherwise>
                            <xsl:value-of select="$str"/>
                        </xsl:otherwise>
                    </xsl:choose>
                </xsl:variable>

                <xsl:element name="{$element-name}"/>
                <xsl:call-template name="elementifier">
                    <xsl:with-param name="str" select="substring-after($str,',')"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise/>
        </xsl:choose>

    </xsl:template>

</xsl:stylesheet>

Answer 2

使用XSLT 2.0，您可以进行字符串操作，然后就可以处理一系列字符串。

<xsl:param name="str1" select="'[Apple,Pie,Pizza]'"/>

<xsl:for-each select="tokenize(replace($str1, '^\[|\]$', ''), ',')">
  <xsl:element name="{.}"/>
</xsl:for-each>

从String创建元素列表

2 个答案: