Question

我想在pi演算的过渡关系的派生上定义一个大小保留函数。我不能说服阿格达它确实保持尺寸。我也收到一条看似非感性的错误信息，所以也许那里有一条线索。

我尽可能地将代码煮熟，同时仍然保留了设置的味道。这是序言。

{-# OPTIONS --sized-types #-}

module SizedTypes where

   open import Data.Product public hiding (swap)
   open import Relation.Binary.PropositionalEquality
   open import Size

   -- Processes.
   data Proc : Set where
      ν_ : Proc → Proc

   -- Actions.
   data ⟿ᵇ : Set where
      input : ⟿ᵇ
      boundOut : ⟿ᵇ

   data ⟿ᶜ : Set where
      out : ⟿ᶜ

   data ⟿ : Set where
      _ᵇ : ⟿ᵇ → ⟿
      _ᶜ : ⟿ᶜ → ⟿

   -- Renamings.
   data Ren : Set where

   postulate
      push : Ren
      swap : Ren
      _ᴬ*_ : Ren → ⟿ᶜ →  ⟿ᶜ

   -- Transitions.
   data _—[_]→_ : {ι : Size} → Proc → (a : ⟿) → Proc → Set where
      ν•_ : ∀ {ι P R} → _—[_]→_ {ι = ι} P (out ᶜ) R →
            _—[_]→_ {ι = ↑ ι} (ν P) (boundOut ᵇ) R
      νᵇ_ : ∀ {ι P R} {a : ⟿ᵇ} → _—[_]→_ {ι = ι} P (boundOut ᵇ) R →
            _—[_]→_ {ι = ↑ ι} (ν P) (a ᵇ) (ν R)
      νᶜ_ : ∀ {ι P R} → _—[_]→_ {ι = ι} P ((push ᴬ* out) ᶜ) R →
            _—[_]→_ {ι = ↑ ι} (ν P) (out ᶜ) (ν R)

   infixl 0 _—[_]→_

   postulate
      _ᴾ*_ : Ren → Proc → Proc
      _ᵀ*_ : ∀ {ι} (ρ : Ren) {P R} {a : ⟿ᶜ} → _—[_]→_ {ι = ι} P (a ᶜ) R →
             _—[_]→_ {ι = ι} (ρ ᴾ* P) ((ρ ᴬ* a) ᶜ) (ρ ᴾ* R)
      swap-involutive : ∀ (P : Proc) → swap ᴾ* swap ᴾ* P ≡ P
      swap∘push : swap ᴬ* push ᴬ* out ≡ out

   infixr 8 _ᵀ*_ _ᴾ*_ _ᴬ*_

   -- Structural congruence.
   infix 4 _≅_
   data _≅_ : Proc → Proc → Set where
      νν-swap : ∀ P → ν (ν (swap ᴾ* P)) ≅ ν (ν P)

现在这是我无法开展的工作。

   -- "Residual" of a transition E after a structural congruence φ.
   ⊖ : ∀ {ι P P′} {a : ⟿} {R} (E : _—[_]→_ {ι = ι} P a R) (φ : P ≅ P′) →
       Σ[ R ∈ Proc ] _—[_]→_ {ι = ι} P′ a R
   ⊖ (ν•_ (νᶜ E)) (νν-swap P) with swap ᵀ* E
   ... | swap*E rewrite swap-involutive P | swap∘push =
      _ , {!!} -- νᵇ (ν• swap*E)
   ⊖ E φ = {!!}

粗略地说，我匹配存在相邻ν活页夹的情况，并且表明如果我转置活页夹（通过在活页夹下应用'交换'重命名），则推导中的相关步骤也会转置。直观地，这保留了转换推导的大小。

切换隐藏的参数（在Emacs中）显示有问题的子句中的目标具有类型_—[_]→_ {↑ (↑ .ι)}，因此我希望能够应用两个构造函数（在这种情况下为νᵇ和ν•）。我还可以看到E的类型为_—[_]→_ {.ι}，swap*E也是如此，所以我（天真地）期望νᵇ (ν• swap*E)与目标大小一致。然而，Agda抱怨约束不一致。

奇怪的是，如果我使用with子句将ν• swap*E引入上下文，那么我会收到以下错误：

.ι !=< P of type Size
when checking that the expression E has type
swap ᴾ* P —[ (push ᴬ* out) ᶜ ]→ .R

这令人困惑，因为元变量P的选择表明Agda试图将大小索引与Proc类型的变量进行匹配。

我在这里做错了什么？

Answer 1

感谢Andrea Vezzosi在Agda邮件列表上回答这个问题。在这种情况下，它就像明确传递ι索引一样简单：

⊖ (ν• (νᶜ_ {ι} E)) (νν-swap P) with swap ᵀ* E
   ... | swap*E rewrite swap-involutive P | swap∘push
     = _ , νᵇ (ν•_ {ι = ι} swap*E)

Answer 2

原来这是一个bug fixed in Agda 2.4.0.2。现在可以简单地写一下：

⊖ (ν• (νᶜ E)) (νν-swap P) with swap ᵀ* E
   ... | swap*E rewrite swap-involutive P | swap∘push
     = _ , νᵇ (ν• swap*E)

人们期待的是

。

不可解决的大小限制

2 个答案: