Question

这听起来很愚蠢，但我无法让它发挥作用。我想我只是不明白%%v, %v% and %v

之间的区别

这是我正在尝试做的事情：

for %%v in (*.flv) do ffmpeg.exe -i "%%v" -y -f mjpeg -ss 0.001 -vframes 1 -an "%%v.jpg"

这为每部电影成功生成缩略图，但问题是：

movie.flv -> movie.flv.jpg

所以我想做的是将%%v中的最后4个字符拉出来并将其用于第二个变量。

我一直在尝试这样的事情：

%%v:~0,-3%

但是它不起作用，也没有任何我能想到的迭代。

有什么想法吗？

Answer 1

对于那些发现此线程正在寻找如何在for-loop变量上实际执行字符串操作的人（使用delayed expansion）：

setlocal enabledelayedexpansion

...

::Replace "12345" with "abcde"
for %%i in (*.txt) do (
    set temp=%%i
    echo !temp:12345=abcde!
)

Answer 2

for %%v in (*.flv) do ffmpeg.exe -i "%%v" -y -f mjpeg -ss 0.001 -vframes 1 -an "%%~nv.jpg"

来自“帮助”：

%~I         - expands %I removing any surrounding quotes (")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string

Answer 3

使用%% ~nV仅获取文件名。

Answer 4

我不像以上那样擅长批处理（我使用WSH或其他脚本语言），但我可以尝试解释%% v％v和％v％。

前两个表单用于for循环。 help for解释了区别，第一种形式用于批处理文件，而第二种形式用于在命令提示符下直接键入（粘贴）命令。

最后一个表单只是将变量名称（环境变量）替换为其值：

set FOO=C:\bar\foo
cd %FOO%\gah

Answer 5

我更喜欢的另一种方法是创建一个子例程（：processMpeg），我为For循环中的每个元素调用，我传递%% v变量。

for %%v in (*.flv) do call :processMpeg "%%v"
goto :eof

:processMpeg
  set fileName=%~n1
  echo P1=%1  fileName=%fileName%  fullpath=%~dpnx1
  ffmpeg.exe -i "%~1" -y -f mjpeg -ss 0.001 -vframes 1 -an "%filename%.jpg"
  goto :eof

如何在for循环中对变量执行字符串操作？

5 个答案: