Question

我正在为我赢得的计算机语言编写一个编译器。现在，在编译语言之前，我实际上需要通过命令行vbs程序用百分比（％）替换所有撇号（'）。但是如果在它前面没有回旋重音（^），则只需要替换撇号。例如，在此代码中：

color 0a

输入十二= 0a“嗨！那太棒了！”

执行：testfornum'122'

出口

：testfornum

如果是数字（'1）（

返回

）ELSE（

打印0a“oops'12'应为数字”

）

返回

第2行的撇号不应该被替换，但第3,6和9行的撇号应该是。

任何人都可以帮助我吗？

这是我到目前为止所做的：

'syntax: (cscript) replace.vbs [filename] "StringToFind" "stringToReplace"

Option Explicit
Dim FileScriptingObject, file, strReplace, strReplacement, fileD, lastContainment,        newContainment

file=Wscript.arguments(0)
strReplace=WScript.arguments(1)
strReplacement=WScript.arguments(2)

Set FileScriptingObject=CreateObject("Scripting.FileSystemObject")
if FileScriptingObject.FileExists(file) = false then
    wscript.echo "File not found!"
    wscript.Quit
end if

set fileD=fileScriptingobject.OpenTextFile(file,1)
lastContainment=fileD.ReadAll

newContainment=replace(lastContainment,strReplace,strReplacement,1,-1,0)
set fileD=fileScriptingobject.OpenTextFile(file,2)
fileD.Write newContainment
fileD.Close

Answer 1

由于@ Ansgar的解决方案因领导＆＃39;的特殊情况而失败。（之前没有非^），这是一种在测试脚本中使用替换函数的方法，这使得进一步的实验变得容易：

Option Explicit

Function fpR(m, g1, g2, p, s)
  If "" = g1 Then
     fpR = "%"
  Else
     fpR = m
  End If
End Function

Function qq(s)
  qq = """" & s & """"
End Function

Dim rE : Set rE = New RegExp
rE.Global = True
rE.Pattern = "(\^)?(')"
Dim rA : Set rA = New RegExp
rA.Global = True
rA.Pattern = "([^^])'"
'rA.Pattern = "([^^])?'"

Dim s
For Each s In Split(" 'a^'b' a'b'^'c nix a^''b")
    WScript.Echo qq(s), "==>", qq(rE.Replace(s, GetRef("fpR"))), "==>", qq(rA.Replace(s, "$1%"))
Next

输出：

cscript 25221565.vbs
"" ==> "" ==> ""
"'a^'b'" ==> "%a^'b%" ==> "'a^'b%"     <=== oops
"a'b'^'c" ==> "a%b%^'c" ==> "a%b%^'c"
"nix" ==> "nix" ==> "nix"
"a^''b" ==> "a^'%b" ==> "a^'%b"

Answer 2

使用普通的字符串替换不能执行此操作。但是正则表达式可以起作用：

...
Set re = New RegExp
re.Pattern = "(^|[^^])'"
re.Global  = True

newContainment = re.Replace(lastContainment, "$1%")
...

VBScript中的高级命令行替换命令

2 个答案: