Question

意图：从串口控制arduino uno

工具：

https://github.com/JanStevens/ArduinoPi-Python

我让服务器同时处理我的Mac和我的Model b + Raspberry。在这两种情况下，浏览器的行为如下图所示。

对我来说，看起来服务器已成功将消息发送给Arduino。但是数据在某种程度上会丢失。每次我在浏览器中访问URL时，Arduino板都会重置。我用谷歌搜索，发现接地和复位引脚之间的10uF电容可以防止发生复位。它确实如此，但引脚3不会“高”。我有一个LED + RESISTOR插在引脚3上并相应地接地。我每次访问网址时都能看到Rx指示灯闪烁。因此，我认为Arduino误解了Flask服务器的命令。

OG Arduino代码：

String cmd;
bool cmdRec = false;
void setup()
{
    //Start the connection with the Raspberry Pi
    Serial1.begin(115200);
    // Start the connection with the Laptop, for debugging only!
    //Serial.begin(115200);
}

void loop()
{
    handleCmd();
}

void serialEvent1() {
    while(Serial1.available() > 0) {
        char inByte = (char)Serial1.read();
        if(inByte == ':') {
            cmdRec = true;
            return;
        } else if(inByte == '@') {
            cmd = "";
            cmdRec = false;
            return;
        } else {
            cmd += inByte;
            return;
        }
    }
}

void handleCmd() {
    if(!cmdRec) return;

    // If you have problems try changing this value, 
    // my MEGA2560 has a lot of space
    int data[80];
    int numArgs = 0;

    int beginIdx = 0;
    int idx = cmd.indexOf(",");

    String arg;
    char charBuffer[20];


    while (idx != -1) {
        arg = cmd.substring(beginIdx, idx);
        arg.toCharArray(charBuffer, 16);

        data[numArgs++] = atoi(charBuffer);
        beginIdx = idx + 1;
        idx = cmd.indexOf(",", beginIdx);
    }
    // And also fetch the last command
    arg = cmd.substring(beginIdx);
    arg.toCharArray(charBuffer, 16);
    data[numArgs++] = atoi(charBuffer);
    // Now execute the command
    execCmd(data);

    cmdRec = false;
}

// For advanced function like switch all the leds in RGB
void execCmd(int* data) {
    switch(data[0]) {
    case 101:
        {
            for(int i = 2; i < (data[1]*2)+1; i+=2) {
                pinMode(data[i], OUTPUT);
                analogWrite(data[i], data[i+1]);
            }
        }
        break;

    case 102:
        {
            pinMode(data[1], INPUT);
            int sensor = analogRead(data[1]);
            Serial1.println(sensor);
        }
        break;

    case 103:
        {
            String result = "";
            int sensor = 0;
            for(int j = 2; j < data[1]+2; j++) {
                pinMode(data[j], INPUT);
                sensor = analogRead(data[j]);
                result += String(sensor)+",";
            }
            Serial1.println(result);
        }
        break;
    default:
        {
            pinMode(data[0], OUTPUT);
            analogWrite(data[0], data[1]);
        }
        break;
    }
}

它不会以这种方式编译。所以我取消注释了第二个Serial.begin行并删除了所有的“Serial1”。出现在代码上。当我在我的mac上测试它时，我看不到对arduino IDE序列的操作。

Answer 1

由于代码是使用带有2个或3个串行端口的Arduino Mega编写的，因此当MEGA的SERIAL1端口进行通信时会触发void serialevent1（）。由于我在UNO上工作，只有1个串口，我所要做的就是删除括号前的“1”，并按照假设进行操作。

void serialEvent() { }

ArduinoPI Python - 串行连接丢失数据

1 个答案: