Question

我可以在Fortran 90中创建函数指针，代码如

real, external :: f

然后使用f作为另一个函数/子例程的参数。但是，如果我想要一个数组的函数指针怎么办？在C中我会做

double (*f[])(int);

创建一个返回double并取整数参数的函数数组。我尝试过最明显的，

real, external, dimension(3) :: f

但gfortran不允许我混合使用EXTERNAL和DIMENSION。有什么办法可以做我想要的吗？（这个上下文是一个求解微分方程组的程序，所以我可以在子程序中输入方程而没有一百万个参数。）

Answer 1

声明“real，external :: f”并没有真正将“f”变成一个完整的指针，因为你无法改变它指向的过程 - 它允许你将这个单个函数传递给另一个例程那么你还需要“指针”属性。 Metcalf，Reid＆amp; Sons的“Fortran 95/2003解释”第267页有一些例子。科恩 - 谷歌搜索“fortran程序指针”将显示此页面。一个接近你的简单例子是“real，external，pointer :: f_ptr”。或者：“procedure（f），pointer :: f_ptr”。这是Fortran 2003功能 - http://gcc.gnu.org/wiki/Fortran2003和http://gcc.gnu.org/wiki/ProcedurePointers列出了gfortran中的部分支持，最好是4.5。我不确定是否直接允许“维度”，但您可以为指针分配一个过程，这提供了很大的灵活性。您还可以将指针放入派生类型，该类型可以制作成数组。

编辑：这是一个与gfortran 4.5一起使用的代码示例：编辑2：行评论下面的评论。

module ExampleFuncs

  implicit none

contains

function f1 (x)
  real :: f1
  real, intent (in) :: x

  f1 = 2.0 * x

  return
end function f1


function f2 (x)
   real :: f2
   real, intent (in) :: x

   f2 = 3.0 * x**2

   return
end function f2


function fancy (func, x)

   real :: fancy
   real, intent (in) :: x

   interface AFunc
      function func (y)
         real :: func
         real, intent (in) ::y
      end function func
   end interface AFunc

   fancy = func (x) + 3.3 * x

end function fancy

end module  ExampleFuncs

program test_proc_ptr

  use ExampleFuncs

  implicit none

  ! REMOVE: pointer :: func
  interface
     function func (z)
        real :: func
        real, intent (in) :: z
     end function func
  end interface

  procedure (func), pointer :: f_ptr => null ()

  type Contains_f_ptr
     procedure (func), pointer, nopass :: my_f_ptr
  end type Contains_f_ptr

  type (Contains_f_ptr), dimension (2) :: NewType


  f_ptr => f1
  write (*, *) f_ptr (2.0)
  write (*, *) fancy (f_ptr, 2.0)

  f_ptr => f2
  write (*, *) f_ptr (2.0)
  write (*, *) fancy (f_ptr, 2.0)

  NewType(1) % my_f_ptr => f1
  NewType(2) % my_f_ptr => f2

  write (*, *) NewType(1) % my_f_ptr (3.0), NewType(2) % my_f_ptr (3.0)

  stop

end program test_proc_ptr

Fortran中的函数指针数组

1 个答案: