Question

如何在QML中设置Button控件中文本的字体大小？设计器没有选项，'font'不是Button的有效属性。

Button {
    id: cmdQuit
    text: qsTr("Quit")
    width: 64
    height: 32
}

Answer 1

您设置了按钮的style属性：

import QtQuick 2.2
import QtQuick.Controls 1.2
import QtQuick.Controls.Styles 1.2

Rectangle {
  id: container
  width: 800
  height: 800

  Button {
    id: cmdQuit
    text: qsTr("Quit")
    width: 64
    height: 32
    style: ButtonStyle {
      label: Text {
        renderType: Text.NativeRendering
        verticalAlignment: Text.AlignVCenter
        horizontalAlignment: Text.AlignHCenter
        font.family: "Helvetica"
        font.pointSize: 20
        color: "blue"
        text: control.text
      }
    }
  }
}

Answer 2

对于QtQuick 2，您必须使用contentItem属性，如下所示：https://doc.qt.io/qt-5/qtquickcontrols2-customize.html#customizing-button

import QtQuick 2.12
import QtQuick.Controls 2.12

Button {
    id: control
    text: qsTr("Button")

    contentItem: Text {
        text: control.text
        font: control.font
        font.pointSize: 20
        opacity: enabled ? 1.0 : 0.3
        color: control.down ? "#17a81a" : "#21be2b"
        horizontalAlignment: Text.AlignHCenter
        verticalAlignment: Text.AlignVCenter
        elide: Text.ElideRight
    }
}

Answer 3

这是一个老问题，但由于它首先出现在搜索引擎中，因此我将提供有关情况的最新信息。

对于 QtQuick2，与 Chris 所说的不同，您不再需要使用 contentItem 属性。您可以直接从 font 访问 Button 属性。

示例：

Button {
    id: btn
    text: "Test"
    font.pixelSize: 18
}

在Qt QML中更改按钮的字体大小

3 个答案: