Question

我再次尝试掌握XSLT的潜力。我遇到过<xsl:copy-of select=""/>就足够了的情况。如下所示：

<xsl:copy-of select="Instructors"/>

但是，XML如下：

<Instructors>
    <Lecturer>
        <First_Name>Jerry</First_Name>
        <Middle_Initial>R.</Middle_Initial>
        <Last_Name>Cain</Last_Name>
    </Lecturer>
    <Professor>
        <First_Name>Eric</First_Name>
        <Last_Name>Roberts</Last_Name>
    </Professor>
    <Professor>
        <First_Name>Mehran</First_Name>
        <Last_Name>Sahami</Last_Name>
    </Professor>
</Instructors>

输出如下：

Jerry R. Cain Eric Roberts Mehran Sahami

我想要的输出（并且可以用模板完成）将是：

Lecturer: Jerry R. Cain
Professor: Eric Roberts
Professor: Mehran Sahami

正如您所看到的，“教师”节点内部实际上有更详细的信息，但是当我使用<xsl:copy-of select="Instructors"/>时，它只输出子节点的值。我知道这是预期的输出，但我想知道是否可以通过操纵<xsl:copy-of select="Instructors"/>来显示一些节点名称来避免制作另一个模板。

提前致谢并抱歉这个相当含糊的问题。

Answer 1

我想知道我是否可以避免制作另一个模板操纵<xsl:copy-of select="Instructors"/>来展示一些节点名称。

没有。 XSLT很冗长。只需编写代码。

Answer 2

使用 xsl：apply-templates ，而不是使用 xsl：copy-of 。在这种情况下，您可以直接找到教师节点

的子节点

<xsl:apply-templates select="Instructors/*"/>

然后你可以有一个匹配孩子的模板，将使用

<xsl:template match="Instructors/*">

在此，您将输出文本。例如，要获得“Lecturer”或“Professor”，您可以这样做：

 <xsl:value-of select="name()" />

试试这个XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="text" />
   <xsl:template match="/">
      <xsl:apply-templates select="Instructors/*"/>
   </xsl:template>

   <xsl:template match="Instructors/*">
      <xsl:value-of select="name()" />
      <xsl:text>: </xsl:text>
      <xsl:value-of select="concat(First_Name, ' ', Last_Name)" />
      <xsl:text>&#10;</xsl:text>
   </xsl:template>
</xsl:stylesheet>

请注意， xsl：copy-of 应复制元素和文本值。但是，如果输出方法是文本，则只输出文本值。

Answer 3

我对Tim C的回答略有改变：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

    <xsl:output method="text"/>    

    <xsl:template match="/">
        <xsl:apply-templates select="Instructors/*"/>
    </xsl:template>

    <xsl:template match="Instructors/*">
        <xsl:value-of select="name()"/>
        <xsl:text>: </xsl:text>
        <xsl:for-each select="*">
            <xsl:if test="position() &gt; 1">
                <xsl:text> </xsl:text>
            </xsl:if>
            <xsl:value-of select="."/>
        </xsl:for-each>
        <xsl:text>&#xA;</xsl:text>
    </xsl:template>

</xsl:stylesheet>

处理<xsl：copy-of> </xsl：copy-of>中返回的值

3 个答案: