Question

我有这段代码只提取活动工作表并将其发送到特定的电子邮件。我在该表上有一个6个CommandButtons，它们附加到某些代码上。因此，在发送代码之前，我需要在此（发送）代码中实现一些代码以删除所有CB-s及其中的所有代码。它会缩小发送文件的次数。

Private Sub CommandButton5_Click()
'Working in Excel 2000-2013
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm

    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim OutApp As Object
    Dim OutMail As Object
    Dim x As Integer


    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set Sourcewb = ActiveWorkbook

    'Copy the ActiveSheet to a new workbook
    ActiveSheet.Copy
    Set Destwb = ActiveWorkbook

    'Determine the Excel version and file extension/format
    With Destwb
        If Val(Application.Version) < 12 Then
            'You use Excel 97-2003
            FileExtStr = ".xls": FileFormatNum = -4143
        Else
            'You use Excel 2007-2013
            Select Case Sourcewb.FileFormat
            Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
            Case 52:
                If .HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsx": FileFormatNum = 51
                End If
            Case 56: FileExtStr = ".xls": FileFormatNum = 56
            Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
            End Select
        End If
    End With

    '    'Change all cells in the worksheet to values if you want
    '   With Destwb.Sheets(1).UsedRange
    '       .Cells.Copy
    '       .Cells.PasteSpecial xlPasteValues
    '       .Cells(1).Select
    '   End With
    '   Application.CutCopyMode = False

    'Save the new workbook/Mail it/Delete it
    TempFilePath = Environ$("temp") & "\"
    TempFileName = "Pregled " & Sourcewb.Name & " " & Format(Now, "dd-mmm-yy h-mm-ss")

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With Destwb
    ActiveSheet.Shapes("CommandButton1").Delete  'this only deletes the CB-s
    ActiveSheet.Shapes("CommandButton2").Delete
    ActiveSheet.Shapes("CommandButton3").Delete
    ActiveSheet.Shapes("CommandButton4").Delete
    ActiveSheet.Shapes("CommandButton5").Delete
    ActiveSheet.Shapes("CommandButton6").Delete



        .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
        On Error Resume Next
        With OutMail
            .To = "exemple@email.ba"
            .CC = ""
            .BCC = ""
            .Subject = "Izvještaj za kutije"
            .Body = "Izvještaj u prilogu! LP."
            .Attachments.Add Destwb.FullName
            'You can add other files also like this
            '.Attachments.Add ("C:\test.txt")
            .Send   'or use .Display
        End With
        On Error GoTo 0
        .Close savechanges:=False
    End With

    'Delete the file you have send
    Kill TempFilePath & TempFileName & FileExtStr

    Set OutMail = Nothing
    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

Answer 1

将文件（如果您愿意，使用宏）保存为.xlsx文件而不是.xlsm。

假设您要保存Sheet1，Sheet2：

Sub SaveAsXSLX()
    Worksheets(Array("Sheet1", "Sheet2")).Copy
    ActiveWorkbook.SaveAs fileName:="NewFileName.xlsx"
end sub

此方法应防止警告消息弹出（错误消息如“无法将此格式保存为非宏格式”）。

在通过电子邮件发送之前删除工作表上的所有VBA代码

1 个答案: