sdk \ tools文件夹中缺少Android.bat文件，我也没有AVD＆amp;工具中的SDK管理器，所以我可以替换它们

Question

我还从我的备份SDK复制了android.bat，但它仍然无法正常工作。 提前谢谢。

Answer 1

可能还缺少sdk / tools文件夹的所有内容？

解决此问题的最佳方法是转到sdk / temp文件夹。 在那里你会找到一个名为＆＃34; tools_r24.0.1-windows＆＃34;的zip文件。 （版本号将有所不同）

将其复制到某个地方并将其解压缩。在解压缩的文件夹中，您将拥有一个名为＆＃39; tools＆＃39;

的文件夹

将该文件夹复制到sdk /并替换sdk /

中的当前工具文件夹

瞧！ SDK和AVD将再次运行，您的所有虚拟设备都将恢复！

Answer 2

我所拥有的最佳解决方案是从http://developer.android.com/sdk/index.html

下载SDK工具

- ＆gt;其他下载选项 - ＆gt;仅限SDK工具 - ＆gt; android-sdk_r24。*。* - windows.zip
更新：现在更新了网页内容，您需要转到以下部分

  

“只获取命令行工具”（根据您的操作系统下载工具）

。
并将其提取到所需工具的sdk位置。

Answer 3

我实际上不明白，为什么你不从其他地方下载它，但这里是Android.bat：

@echo off
rem Copyright (C) 2007 The Android Open Source Project
rem
rem Licensed under the Apache License, Version 2.0 (the "License");
rem you may not use this file except in compliance with the License.
rem You may obtain a copy of the License at
rem
rem      http://www.apache.org/licenses/LICENSE-2.0
rem
rem Unless required by applicable law or agreed to in writing, software
rem distributed under the License is distributed on an "AS IS" BASIS,
rem WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
rem See the License for the specific language governing permissions and
rem limitations under the License.

rem Useful links:
rem Command-line reference:
rem   http://technet.microsoft.com/en-us/library/bb490890.aspx

rem don't modify the caller's environment
setlocal

rem Set up prog to be the path of this script, including following symlinks,
rem and set up progdir to be the fully-qualified pathname of its directory.
set prog=%~f0

rem Grab current directory before we change it
set work_dir=%cd%

rem Change current directory and drive to where the script is, to avoid
rem issues with directories containing whitespaces.
cd /d %~dp0


rem Check we have a valid Java.exe in the path.
set java_exe=
call lib\find_java.bat
if not defined java_exe goto :EOF

set jar_path=lib\sdkmanager.jar;lib\swtmenubar.jar

rem Set SWT.Jar path based on current architecture (x86 or x86_64)
for /f "delims=" %%a in ('"%java_exe%" -jar lib\archquery.jar') do set swt_path=lib\%%a

:MkTempCopy
    rem Copy android.bat and its required libs to a temp dir.
    rem This avoids locking the tool dir in case the user is trying to update it.

    set tmp_dir=%TEMP%\temp-android-tool
    xcopy %swt_path% %tmp_dir%\%swt_path% /I /E /C /G /R /Y /Q > nul
    copy /B /D /Y lib\common.jar         %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\commons-codec*     %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\commons-compress*  %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\commons-logging*   %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\dvlib.jar          %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\guava*             %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\httpclient*        %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\httpcore*          %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\httpmime*          %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\layoutlib-api.jar  %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\org-eclipse-*      %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\sdk*               %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\swtmenubar.jar     %tmp_dir%\lib\        > nul

    rem jar_path and swt_path are relative to PWD so we don't need to adjust them, just change dirs.
    set tools_dir=%cd%
    cd /d %tmp_dir%

:EndTempCopy

rem The global ANDROID_SWT always override the SWT.Jar path
if defined ANDROID_SWT set swt_path=%ANDROID_SWT%

if exist "%swt_path%" goto SetPath
    echo ERROR: SWT folder '%swt_path%' does not exist.
    echo Please set ANDROID_SWT to point to the folder containing swt.jar for your platform.
    goto :EOF

:SetPath
rem Finally exec the java program and end here.
REM set REMOTE_DEBUG=-Xdebug -Xrunjdwp:transport=dt_socket,server=y,suspend=y,address=8000
call "%java_exe% %REMOTE_DEBUG%" "-Dcom.android.sdkmanager.toolsdir=%tools_dir%" "-Dcom.android.sdkmanager.workdir=%work_dir%" -classpath "%jar_path%;%swt_path%\swt.jar" com.android.sdkmanager.Main %*

rem EOF

Answer 4

我最终下载了Android Studio Bundle（android-studio-bundle-143.2915827-windows.exe），然后我用7Zip打开了它，在$ TEMP目录中，有一个android-sdk.7z文件。我解压缩并将工具文件夹复制回来。

我不确定我是如何删除它的，但我有一个这样的HiDpi屏幕，当我打开SDK Manager时，我想我点击了＆＃ 34;更新＆＃34;按钮，但事实证明你无法看到整个单词，它实际上是＆＃34;删除＆＃34;按钮。

一个工具允许自我删除的原因超出了我的范围.....

Answer 5

这是来自Google的tools文件夹和android.bat文件的实际路径。

https://android.googlesource.com/platform/prebuilts/devtools/+/jb-mr2-dev/tools/

https://android.googlesource.com/platform/prebuilts/devtools/+/jb-mr2-dev/tools/android.bat

更新：您可以克隆devtools文件夹并从那里获取所有文件

git clone https://android.googlesource.com/platform/prebuilts/devtools

花费超过半天的时间尝试设置Java，Android，环境变量并复制粘贴的.bat文件。希望这可以节省一些时间。