Question

我有以下代码：

    Program function_as_an_array
    implicit none
    integer:: i
    integer, parameter:: N=10
    real*8:: x(N),y(N),f(N)

    do i=1,N
      x(i)=float(i)
    end do

    call func(f,N,x)

    open(unit=20, file='test.dat')
    do i=1,N
      y(i)=f(i)
      write(20,*) x(i),y(i) 
    end do
    close(20)
    Stop 
    End Program function_as_an_array


    Subroutine func(f,N,x)
    implicit none
    integer i,N
    real*8:: x(N),f(N) 

    do i=1,N
       f(i)=x(i)**2
    end do

    end Subroutine func

我想让这个程序确实适合＆＃34;作为arrray＆＃34;起作用，即我想用Subroutine func替换function f并获得相同的结果（在主程序中，我希望保留一个像{{ {1}}）。我怎么能这样做？

感谢。

Answer 1

函数返回一个数组没有问题，就像this question and answer一样：主要的问题是你需要函数在一个模块中（或程序中的contain）以便有一个自动显式界面：（编辑添加：或明确定义界面，与Alexander Vogt的答案一样）

module functions
contains

    function func(N,x)
    implicit none
    integer, intent(in) :: N
    double precision, intent(in) :: x(N)
    double precision, dimension(N) :: func

    integer :: i

    do i=1,N
       func(i)=x(i)**2
    end do

end function func

end module functions

Program function_as_an_array
use functions
implicit none
integer:: i
integer, parameter:: N=10
double precision:: x(N),y(N)

do i=1,N
  x(i)=float(i)
end do

y = func(N,x)

open(unit=20, file='test.dat')
do i=1,N
  write(20,*) x(i),y(i)
end do
close(20)
Stop
End Program function_as_an_array

但请注意，这种函数 - 对数组中的每个元素应用相同的操作 - 使用Fortran elemental函数做得更好一些，定义为仅在标量上工作，Fortran会自动将其映射到数组的所有元素：

module functions
contains

    elemental double precision function f(x)
    implicit none
    double precision, intent(in) :: x

    f = x**2

    end function f

end module functions

Program function_as_an_array
    use functions
    implicit none
    integer:: i
    integer, parameter:: N=10
    double precision:: x(N),y(N)

    do i=1,N
      x(i)=float(i)
    end do

    y = f(x)

    open(unit=20, file='test.dat')
    do i=1,N
      write(20,*) x(i),y(i)
    end do
    close(20)
    Stop
End Program function_as_an_array

关于这一点的好处是它现在可以自动处理标量和任何等级的数组。只要有可能，让编译器为您完成工作是件好事。

Answer 2

这对我有用：

Program function_as_an_array
implicit none
integer:: i
integer, parameter:: N=10
real*8 :: x(N),y(N),f(N)
interface func
  function func(x,N) result(f)
    implicit none
    integer N
    real*8:: x(N),f(N) 
  end function
end interface

do i=1,N
  x(i)=float(i)
end do

f = func(x,N)

open(unit=20, file='test.dat')
do i=1,N
  y(i)=f(i)
  write(20,*) x(i),y(i) 
end do
close(20)
Stop 
End Program function_as_an_array


function func(x,N) result(f)
implicit none
integer i, N
real*8:: x(N),f(N) 

do i=1,N
   f(i)=x(i)**2
end do

end function

你需要：

使用result获取数组值的返回变量 [edit] ，或将func指定为real*8:: func(N)。有关详细信息，请参阅注释
使用外部函数的显式接口（或具有隐式接口的模块，请参阅Jonathan Dursi的回答）

然后，您可以直接将函数的返回值分配给数组。

定义返回数组的函数

2 个答案: