Question

我有一个从莲花笔记下载附件的代码。问题是每次运行时都会下载所有附件。如何给出不下载以前下载的附件的条件？

Option Explicit
Sub Save_Attachments_Remove_Emails()

Const stPath As String = "c:\Attachments\"
Const EMBED_ATTACHMENT As Long = 1454
Const RICHTEXT As Long = 1

Dim noSession As Object
Dim noDatabase As Object
Dim noView As Object
Dim noDocument As Object
Dim noRemoveDocument As Object
Dim noNextDocument As Object

'Embedded objects are of the datatype Variant.
Dim vaItem As Variant
Dim vaAttachment As Variant

'Instantiate the Notes session.
Set noSession = CreateObject("Notes.NotesSession")

'Instantiate the actual Notes database.
'(Here is the personal e-mail database used and since it's a
'local database no reference is made to any server.)
Set noDatabase = noSession.GETDATABASE("CAT-DH-23.apd.cat.com/Servers/Caterpillar", "mail\pamsmine.nsf")
' Please use this Open Function if the server is not referenced and GETDATABASE
' opens the db file if the file is in local system.
'Call noDatabase.Open("", "C:\notes\test.nsf")

'Folders are views in Lotus Notes and in this example the Inbox
'is used.
Set noView = noDatabase.GetView("($Inbox)")

'Get the first document in the defined view.
Set noDocument = noView.GetFirstDocument

'Iterate through all the e-mails in the view Inbox.
Do Until noDocument Is Nothing
Set noNextDocument = noView.GetNextDocument(noDocument)
'Check if the document has an attachment or not.
If noDocument.HasEmbedded Then
  Set vaItem = noDocument.GetFirstItem("Body")
  If vaItem.Type = RICHTEXT Then
    For Each vaAttachment In vaItem.EmbeddedObjects
     If vaAttachment.Type = EMBED_ATTACHMENT Then
        'Save the attached file into the new folder.
        vaAttachment.ExtractFile stPath & vaAttachment.Name
        'Set the e-mail object which will be deleted.
        Set noRemoveDocument = noDocument
      End If
    Next vaAttachment
  End If
End If
Set noDocument = noNextDocument
'Delete the e-mails which have an attached file.
' If Not noRemoveDocument Is Nothing Then
 ' noRemoveDocument.Remove (True)
 ' Set noRemoveDocument = Nothing
'End If
Loop

'Release objects from memory.
Set noRemoveDocument = Nothing
Set noNextDocument = Nothing
Set noDocument = Nothing
Set noView = Nothing
Set noDatabase = Nothing
Set noSession = Nothing

MsgBox "All the attachments in the Inbox have successfully been saved" & vbCrLf & _
     "and the associated e-mails have successfully been deleted.", vbInformation

End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

End Sub

Answer 1

如果所有附件都是唯一命名的，并且目标路径仅包含下载的文件，则可以使用VBA轻松检查附件是否已经存在（即没有下载） Dir函数：http://msdn.microsoft.com/en-us/library/dk008ty4(v=vs.90).aspx（我从未测试过VB.Net行为，只测试了VBA，但看起来非常相似）。

您可能想写：

' Previous code [...]
' If is an attachment ...
If vaAttachment.Type = EMBED_ATTACHMENT Then
        ' ...check if was downloaded.
        If Dir(stPath & vaAttachment.Name) = "" Then
                'If not, save the attached file into the folder.
                vaAttachment.ExtractFile stPath & vaAttachment.Name

                'Set the e-mail object which will be deleted.
                Set noRemoveDocument = noDocument
        End If
End If
' Following code [...]

如何使用vb脚本从lotus notes下载附件

1 个答案: