Question

我试图并行化我编写的代码。我在数组上执行reducitons时遇到问题。这一切似乎都适用于小型数组，但是当数组大小超过某一点时，我会遇到堆栈溢出错误或崩溃。

我已经尝试在编译时使用/ F增加堆栈大小，我在Windows上使用ifort，我还尝试将set KMP_STACKSIZE = xxx传递给intel特定的stacksize decleration。这有时可以帮助并允许代码在我的循环中进一步发展，但最终解决不了问题，即使堆栈大小为1Gb或更高。

下面是我的代码的一个小型自包含工作示例。它可以串行工作，并且有一个线程。或者有许多线程，但是很小的N＆＃39; N。大N（即示例中的250,000）会引起问题。

我并不认为这些数组是如此庞大以至于造成重大问题，并且假设增加我的堆栈空间会有所帮助 - 还有其他选择，还是我错过了编码中的重要内容？

program testreduction
    use omp_lib
    implicit none
    integer :: i, j, nthreads, Nsize
    integer iseed /3/
    REAL, allocatable :: A(:,:), B(:), C(:), posi(:,:)
    REAL :: dx, dy, r, Axi, Ayi, m, F
    !Set size of matrix, and main loop
    Nsize = 250000
    m = 1.0
    F = 1.0
    !Allocate posi array
    allocate(posi(2,Nsize))
    !Fill with random numbers
    do i=1,Nsize
        do j=1,2
            posi(j,i) = (ran(iseed))
        end do
    end do
    !Allocate other arrays
    allocate(A(2,Nsize), C(Nsize), B(Nsize))

    print*, sizeof(A)+sizeof(B)+sizeof(C)
    !$OMP parallel
    nthreads = omp_get_num_threads()
    !$OMP end parallel

    print*, "Number of threads ", nthreads
    !Go through each array and do some work, calculating a reduction on A, B and C.
    !$OMP parallel do schedule(static) private(i, j, dx, dy, r, Axi, Ayi) reduction(+:C, B, A)
    do i=1,Nsize
        do j=1,Nsize
            !print*, i
            dx = posi(1,i) - posi(1,j)
            dy = posi(2,i) - posi(2,j)
            r = sqrt(dx**2+dy**2)
            Axi = -m*(F)*(dx/(r))
            Ayi = -m*(F)*(dy/(r))
            A(1,i) = A(1,i) + Axi
            A(2,i) = A(2,i) + Ayi
            B(i) = B(i) + (Axi+Ayi)
            C(i) = C(i) + dx/(r) + dy/(r)
        end do    
    END DO
    !$OMP END parallel do

end program

更新

我正在谈论的一个更好的例子..

program testreduction2
    use omp_lib
    implicit none
    integer :: i, j, nthreads, Nsize, q, k, nsize2
    REAL, allocatable :: A(:,:), B(:), C(:)
    integer, ALLOCATABLE :: PAIRI(:), PAIRJ(:)

    Nsize = 25
    Nsize2 = 19
    q=0

    allocate(A(2,Nsize), C(Nsize), B(Nsize))
    ALLOCATE(PAIRI(nsize*nsize2), PAIRJ(nsize*nsize2))

    do i=1,nsize
        do j =1,nsize2
            q=q+1
            PAIRI(q) = i
            PAIRJ(q) = j
        end do
    end do

    A = 0
    B = 0
    C = 0

    !$OMP parallel do schedule(static) private(i, j, k)
    do k=1,q
        i=PAIRI(k)
        j=PAIRJ(k)
        A(1,i) = A(1,i) + 1
        A(2,i) = A(2,i) + 1
        B(i) = B(i) + 1
        C(i) = C(i) + 1
    END DO
    !$OMP END parallel do

    PRINT*, A
    PRINT*, B
    PRINT*, C       
END PROGRAM

Answer 1

问题是你正在减少非常大的数组。请注意，其他语言（C，C ++）根本无法减少数组。

但是我没有看到任何减少你的情况的理由，你只更新每个元素一次。

尝试

!$OMP parallel do schedule(static) private(i, dx, dy, r, Axi, Ayi)
do i=1,Nsize
  do j=1,Nsize
    ...
    A(1,i) = A(1,i) + Axi
    A(2,i) = A(2,i) + Ayi
    B(i) = B(i) + (Axi+Ayi)
    C(i) = C(i) + dx/(r) + dy/(r)
  end do
end do
!$OMP END parallel do

重点是线程不会介入。每个帖子使用不同的i集合，因此使用A，B和C的不同元素。

即使您提出了一个似乎有必要的案例，您也可以随时重写它以避免它。您甚至可以自己分配一些缓冲区并模拟缩减。或者使用原子更新。

使用Fortran减少Openmp数组

1 个答案: