Bison / YACC vs. Lemon vs.标准输入

Question

我正在尝试将计算器从Bison转换为Lemon。

我遇到了涉及标准输入的意外问题 这两个程序的表现完全不同。野牛版 按[Enter]后立即打印结果。随着 柠檬版，结果推迟到我输入新版本 表达式并按[Enter]。

我创建了微小的Bison和Lemon语法和Flex扫描仪 说明问题。这是在Windows 7上，使用2014年7月 版本的柠檬，野牛2.41和gcc（tdm64-2）4.8.1。

使用Bison版本的简单会话

注意后按[Enter]后如何返回结果 简单的表达。

使用Lemon版本的简单会话

注意结果仅在输入a后返回 第二个表达并按下[Enter]（ctrl Z信号 cmd.exe的输入结束。）

我做错了什么？

Bison / Flex版本源

badd.l：

%{
    #include "y.tab.h"
    #include <stdlib.h>
%}

%%
[0-9]+      {yylval = atoi(yytext); return INTEGER;}
[+]         return PLUS;
[\n]        return NL;
[ \t]       ;       /* skip whitespace */
.           {printf("Unknown character '%c'\n", yytext[0]); return 0;}
%%

int yywrap(void) {
    return 1;
}

badd.y：

%{
    #include <stdio.h>
    int yylex(void);
    void yyerror(char *);
%}

%token INTEGER PLUS NL
%left PLUS MINUS

%%

prog:   prog expr NL                { printf("%d\n", $2); }
        |
        ;
expr:   INTEGER                     { $$ = $1; }
        | expr PLUS expr            { $$ = $1 + $3; }
        ;
%%

void yyerror(char *s) {
    fprintf(stderr, "%s\n", s);
}

int main(void) {
    yyparse();
    return 0;
}

构建：

bison -y -d badd.y
flex badd.l
gcc y.tab.c lex.yy.c -o badd.exe

Lemon / Flex版本源

ladd.l

%{
    #include "ladd.h"
    #include <stdlib.h>
    extern int yylval;
%}

%%
[0-9]+      {yylval = atoi(yytext); return INTEGER;}
[+]         return PLUS;
[\n]        return NL;
[ \t]       ;       /* skip whitespace */
.           {printf("Unknown character '%c'\n", yytext[0]); return 0;}
%%

int yywrap(void) {
    return 1;
}

ladd.y：

%include { #include <assert.h> }
%syntax_error { printf("Lemon syntax error\n"); }
%token_type {int}
%left PLUS MINUS .

start   ::= prog .

prog    ::= prog expr(a) NL .           { printf("%d\n", a); }
prog    ::= .

expr(a) ::= INTEGER(b) .                { a = b; }
expr(a) ::= expr(b) PLUS expr(c) .      { a = b + c; }

main.c中：

#include <stdio.h>
#include <stdlib.h>

void *ParseAlloc(void *(*mallocProc)(size_t));
void ParseFree(void *p, void (*freeProc)(void*));
void Parse(void *yyp, int yymajor, int foo);

int yylex(void);
int yylval;

int main(void) {
   void *pParser;
   int tok;

   pParser = ParseAlloc(malloc);

   while ((tok = yylex()) != 0) {
      Parse(pParser, tok, yylval);
   }
   Parse(pParser, 0, 0);
   ParseFree(pParser, free );

   return 0;
}

构建：

lemon ladd.y
flex ladd.l
gcc main.c ladd.c lex.yy.c -o ladd.exe

Answer 1

如果只有一个可能的减少动作且没有可能的转移动作，则Bison LALR（1）解析器将立即减少。 （这并不意味着所有前瞻代币都有相同的减少动作。有些可能是错误，但无论如何都会发生减少。）

Lemon没有实现此优化。它总是需要一个先行令牌。 （但是，它也会进行表压缩IIRC，因此即使前瞻标记表明输入格式不正确，它也可以进行减少。这是LALR（1）解析的一个特性。）

解决问题的关键是确保打印表达式值的缩减是使用换行符作为先行标记执行的。在Yacc或Bison中，您可以使用中规则操作执行此操作，但Lemon不实现这些，因此您需要添加单位规则以触发操作，如下所示：

start   ::= prog .

prog    ::= prog print NL .
prog    ::= .

print   ::= expr(a) .         { printf("%d\n", a); }

此处，从expr减少到print仅用于打印表达式的值。

顺便说一句，这个解决方案也适用于Yacc或Bison。它可以说比依靠Bison的前瞻优化要好，据我所知，这并不能保证在所有情况下都能正常工作。