Question

在此catalog.xml文件中。我有两本书有相同的库存（即20）。我想编写一个XSL文件，它将在目录中显示最大数量的书籍副本。如果有两本或两本以上相同库存的书籍，则必须显示它们。

<catalog>
  <Book>
    <sku>12345</sku>
    <title>Beauty Secrets</title>
    <condition>New</condition>
    <current_inventory>20</current_inventory>
    <price>99.99</price>
  </Book>
  <Book>
    <sku>54321</sku>
    <title>Picturescapes</title>
    <current_inventory>20</current_inventory>
    <condition>New</condition>
    <price>50.00</price>
  </Book> 
  <Book>
    <sku>33333</sku>
    <title>Tourist Perspectives</title>
    <condition>New</condition>
    <current_inventory>0</current_inventory>
    <price>75.00</price>
  </Book>
  <Book>
    <sku>10001</sku>
    <title>Fire in the Sky</title>
    <condition>Used</condition>
    <current_inventory>0</current_inventory>
    <price>10.00</price>
  </Book>
</catalog>

以下是我的catalog3.xsl文件，该文件只能显示两本书中的一本：

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:variable name="max"/>

  <xsl:template match="/">
    <html>
      <body>
        <h2>Titles of Books for which Most Copies are Available</h2>
        <table border="2">
          <tr bgcolor="#9acd32">
            <th>Title</th>
            <th>No of Copies</th>
          </tr>
          <xsl:apply-templates/>
        </table>
      </body>
    </html>
  </xsl:template>

  <xsl:template match="catalog">
    <xsl:for-each select="Book">
      <xsl:sort select="current_inventory" data-type="number" order="descending"/>
      <tr>
        <xsl:if test="position()= 1">
          <p><xsl:value-of select="$max = "/></p>
          <td><xsl:value-of select="title"/></td>
          <td><xsl:value-of select="current_inventory"/></td>
        </xsl:if>
      </tr>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

任何人都可以纠正我，以实现我在目录中显示具有相同最大库存的所有副本的目标。感谢。

Answer 1

可以通过以下方式计算最大current_inventory：

<xsl:variable name="max">
  <xsl:for-each select="/catalog/Book/current_inventory">
    <xsl:sort data-type="number" order="descending"/>
    <xsl:if test="position()=1"><xsl:value-of select="."/></xsl:if>
  </xsl:for-each>
</xsl:variable>

调整xsl:if的条件，以便将current_inventory中当前节点的for-each与$max变量进行比较，从而获得所需的结果。

您正在评估position()=1内的for-each，这对于已排序集合中的第一项只会是真的。

我将其设置为查找等于current_inventory的<{1}}：

$max

将这些更改应用于您的样式表：

<xsl:if test="current_inventory = $max">

Answer 2

以下是使用Muenchian分组的解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kBookByNums"
    match="Book" use="number(current_inventory)"/>

 <xsl:template match="/*">
   <xsl:for-each select=
    "Book
      [generate-id()
      =
       generate-id(key('kBookByNums',
                        number(current_inventory)
                       )[1]
                       )
       ]
    ">
     <xsl:sort select="current_inventory"
      data-type="number" order="descending"/>

      <xsl:if test="position()=1">
        <xsl:copy-of select=
          "key('kBookByNums',
                number(current_inventory)
               )"/>
      </xsl:if>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

在提供的XML文档上应用此转换时，会生成正确的结果：

<Book>
<sku>12345</sku>
<title>Beauty Secrets</title>
<condition>New</condition>
<current_inventory>20</current_inventory>
<price>99.99</price>
</Book>
<Book>
<sku>54321</sku>
<title>Picturescapes</title>
<current_inventory>20</current_inventory>
<condition>New</condition>
<price>50.00</price>
</Book>

<强>更新：

似乎这个xsl-key的解决方案“仅为大型输入文档（即成千上万本书）播放其'效率卡'。”正如有人所说的那样。事实上，这样的陈述是非常不精确的。

即使没有太多项目，效率也会提高，如果不同值的数量非常小，则与值总数相比 。因此，即使对于相当小的项目集（一百二十个），如果不同值的数量不超过10-20，则会产生显着影响 - 这在许多真实案例中都会发生。

重要的是不同值与总大小的比率。

Answer 3

此XSLT 1.0样式表

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
>
  <xsl:template match="catalog">
    <!-- find the maximum <current_inventory> of all books -->
    <xsl:variable name="MaxInventory">
      <xsl:for-each select="Book">
        <xsl:sort select="current_inventory" data-type="number" order="descending" />
        <xsl:if test="position() = 1">
          <xsl:value-of select="current_inventory" />
        </xsl:if>
      </xsl:for-each>
    </xsl:variable>

    <!-- output all matching <Book>s, sorted by title -->
    <table>
      <xsl:apply-templates select="Book[current_inventory = $MaxInventory]">
        <xsl:sort select="title" data-type="text" order="ascending" />
      </xsl:apply-templates>
    </table>
  </xsl:template>

  <xsl:template match="Book">
    <tr>
      <td><xsl:value-of select="title" /></td>
      <td><xsl:value-of select="current_inventory" /></td>
    </tr>
  </xsl:template>

</xsl:stylesheet>

产生

<table>
  <tr>
    <td>Beauty Secrets</td>
    <td>20</td>
  </tr>
  <tr>
    <td>Picturescapes</td>
    <td>20</td>
  </tr>
</table>

请注意，存在更有效的解决方案，它涉及XSL密钥（Dimitre Novatchev显示它）。这是一个直截了当且易于理解的，XSL密钥解决方案是先进的，并且仅为大型输入文档（即数千本书）播放其“效率卡”。使用小型输入文档时，性能差异可以忽略不计。

Answer 4

对于XSL来说，这种事情并不好玩。要在库存计数可以是任意的时候在标记中找出“如果有两个或更多相同库存的书籍”，则需要一个数据结构，您可以在其中存储遇到的库存计数。我建议在转换之前遍历XML DOM并对它进行计数（更容易），然后创建一个要转换的节点的新Document并将XSL应用于它。与试图在样式表中实现所有内容相比，这将更直接，更简洁。

XSL在catalog.xml文件中显示最大份数

4 个答案: