Question

我正在尝试更新RichEdit，以便它检测到URL并允许单击它以在浏览器中打开。检测网址很简单，我只使用http://www.scalabium.com/faq/dct0146.htm

中的以下代码

mask := SendMessage(MNote.Handle, EM_GETEVENTMASK, 0, 0);
  SendMessage(MNote.Handle, EM_SETEVENTMASK, 0, mask or ENM_LINK);
  SendMessage(MNote.Handle, EM_AUTOURLDETECT, Integer(True), 0);

但第二部分对我不起作用。他们提供以下代码来捕获EN_LINK消息并对其进行处理：

type
  TForm1 = class(TForm)
  protected
    procedure WndProc(var Message: TMessage); override;
  end;
...

procedure TForm1.WndProc(var Message: TMessage);
var
  p: TENLink;
  strURL: string;
begin
  if (Message.Msg = WM_NOTIFY) then
  begin
    if (PNMHDR(Message.LParam).code = EN_LINK) then
    begin
      p := TENLink(Pointer(TWMNotify(Message).NMHdr)^);
      if (p.msg = WM_LBUTTONDOWN) then
      begin
        SendMessage(RichEdit1.Handle, EM_EXSETSEL, 0, LongInt(@(p.chrg)));
        strURL := RichEdit1.SelText;
        ShellExecute(Handle, 'open', PChar(strURL), 0, 0, SW_SHOWNORMAL);
      end
    end
  end;

  inherited;
end;

当我运行程序时，会检测到URL，但是单击它不会执行任何操作。使用调试我发现当我点击URL时，Message.Msg = WM_NOTIFY不成立。然后我试图覆盖TRichEdit的WndProc，但结果是一样的。有什么建议吗？

Answer 1

对RichEdit的WindowProc属性进行子类化并查找CN_NOTIFY消息，例如：

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    procedure FormCreate(Sender: TObject);
  private
    PrevRichEditWndProc: TWndMethod;
    procedure RichEditWndProc(var Message: TMessage);
    procedure SetRichEditMasks;
  end; 

procedure TForm1.FormCreate(Sender: TObject);
begin
  PrevRichEditWndProc := RichEdit1.WindowProc;
  RichEdit1.WindowProc := RichEditWndProc;
  SetRichEditMasks;
end;

procedure TForm1.SetRichEditMasks;
var
  mask: Longint;
begin
  mask := SendMessage(RichEdit1.Handle, EM_GETEVENTMASK, 0, 0); 
  SendMessage(RichEdit1.Handle, EM_SETEVENTMASK, 0, mask or ENM_LINK); 
  SendMessage(RichEdit1.Handle, EM_AUTOURLDETECT, 1, 0);  
end;

procedure TForm1.RichEditWndProc(var Message: TMessage); 
begin 
  PrevRichEditWndProc(Message);
  case Message.Msg of
    CN_NOTIFY:
      begin
        if (TWMNotify(Message).NMHdr^.code = EN_LINK) then
        begin
          with PENLink(Message.LParam)^ do
          begin
            if (msg = WM_LBUTTONDOWN) then
            begin 
              SendMessage(RichEdit1.Handle, EM_EXSETSEL, 0, LongInt(@chrg)); 
              ShellExecute(Handle, 'open', PChar(RichEdit1.SelText), 0, 0, SW_SHOWNORMAL); 
            end;
          end;
        end;
      end;
    CM_RECREATEWND:
      begin
        SetRichEditMasks;
      end;
  end; 
end;

Answer 2

对我来说，只有当显示的文本与底层超链接的文本相同时，它才有效。

我认为我的问题是底层超链接具有属性CFE_HIDDEN，因此EM_EXSETSEL无法选择。

例如，如果我创建（在WORD中）带有URL http://www.rubbish.com的链接，但显示文本RUBBISH，尽管所选文本的chrg是11-33，即22个字符 - 相同作为URL的长度，方法返回的实际文本是RUBBISH。

但是，我发现如果我使用WM_GETTEXT，则会返回整个链接：

HYPERLINK“http://www.rubbish.com”RUBBISH

我可以根据chrg从中提取URL。

感觉有点笨拙......但它确实有效。： - ）

Answer 3

您是否尝试使用精简版应用程序来确保它不是程序中的其他内容导致问题？我按照Delphi 2009中该网站的步骤进行操作，点击URL工作得很好。

检测点击RichEdit中的URL

3 个答案: