Question

我有一个我上传到sas的数据集。完全相同的顺序总是有4个变量。问题是有时变量的名称可能略有不同。

例如第一个变量user。第二天我得到相同的数据集，它可能是userid。。。所以我不能使用rename(user=my_user)

有什么办法可以按顺序引用变量。。像这样的东西

rename(var_order_1=my_user) ;

rename(var_order_3=my_inc) ;

rename _ALL_=x1-x4 ;

Answer 1

有几种方法可以做到这一点。一种是确定PROC CONTENTS或dictionary.columns中的变量名称并生成重命名语句。

data have;
input x1-x4;
datalines;
1 2 3 4
5 6 7 8
;;;;
run;


%macro rename(var=,newvar=); 
rename &var.=&newvar.;
%mend rename;

data my_vars;   *the list of your new variable names, and their variable number;
length varname $10;
input varnum varname $;
datalines;
1 FirstVar
2 SecondVar
3 ThirdVar
4 FourthVar
;;;;
run;

proc sql;     *Create a list of macro calls to the rename macro from joining dictionary.columns with your data. ;
              * Dictionary.columns is like proc contents.;
select cats('%rename(var=',name,',newvar=',varname,')')
  into :renamelist separated by ' '
  from dictionary.columns C, my_vars M
  where C.memname='HAVE' and C.libname='WORK'
    and C.varnum=M.varnum;
quit;

proc datasets;
modify have;
&renamelist;  *use the calls;
quit;

另一种方法是使用输入流和_INFILE_自动变量（引用输入流中的当前行）来输入/输入数据。这是一个例子。如果你愿意的话，你当然只会保留新的变量。

data have;
input x1-x4;
datalines;
1 2 3 4
5 6 7 8
;;;;
run;

data want;
set have;
infile datalines truncover;   *or it will go to next line and EOF prematurely;
input @1 @@;                  *Reinitialize to the start of the line or it will eventually EOF early;
_infile_=catx(' ',of _all_);  *put to input stream as space delimited - if your data has spaces you need something else;
input y1-y4 @@;               *input as space delimited;
put _all_;                    *just checking our work, for debugging;
datalines;                    *dummy datalines (could use a dummy filename as well);

;;;;
run;

Answer 2

这是使用字典表的另一种方法..

data have;
   format var1-var4 $1.;
   call missing (of _all_);
run;
proc sql noprint;
select name into: namelist separated by ' '  /* create macro var */
   from dictionary.columns
   where libname='WORK' and memname='HAVE' /* uppercase */
   order by varnum; /* should be ordered by this anyway */

%macro create_rename(invar=);
%do x=1 %to %sysfunc(countw(&namelist,%str( )));
   /* OLDVAR = NEWVARx */
   %scan(&namelist,&x) = NEWVAR&x
%end;
%mend;

data want ;
   set have (rename=(%create_rename(invar=&namelist)));
   put _all_;
run;

给出：

NEWVAR1=  NEWVAR2=  NEWVAR3=  NEWVAR4=

如何在不使用原始名称的情况下重命名变量？

2 个答案: