Question

我有一个Datagrid，其中包含从数据库中检索到的信息，我希望打印输出采用包含行和列的表格格式。我的实际方法很简单，但输出非常混乱。有什么想法吗？

  Private Sub Imprimir_Click(sender As Object, e As EventArgs) Handles Imprimir.Click
    PrintPreviewDialog1.PrintPreviewControl.Zoom = 1.0
    PrintPreviewDialog1.FindForm.WindowState = FormWindowState.Maximized
    PrintPreviewDialog1.ShowDialog()
  End Sub

  Private Sub PrintDocument1_PrintPage(ByVal sender As System.Object, ByVal e As 
      System.Drawing.Printing.PrintPageEventArgs) Handles PrintDocument1.PrintPage
      Dim y As Integer = 70
      PrintDocument1.DefaultPageSettings.Landscape = True
      e.Graphics.DrawString("TransporGest - Registo de Operações", 
          New Font("Verdana", 10, FontStyle.Bold), Brushes.Black, 30, 30)
      For Each dr As DataGridViewRow In dg.Rows
        e.Graphics.DrawString(dr.Cells(0).Value & " | " & dr.Cells(2).Value & 
             " | " & dr.Cells(3).Value & " | " & dr.Cells(4).Value & " | " &
             dr.Cells(6).Value & " | " & dr.Cells(7).Value & " | " & 
             dr.Cells(9).Value & " | " & dr.Cells(11).Value & " | " & 
             dr.Cells(12).Value, New Font("Verdana", 10), Brushes.Black, 30, y)
        y += 20
    Next
  End Sub
End Class

Answer 1

添加到表单（设计）Button1，PrintDocument1，PrintPreviewDialog1，您的 - ＆gt; DataGridView1

并粘贴代码：

Dim mRow As Integer = 0
Dim newpage As Boolean = True
Private Sub PrintDocument1_PrintPage(sender As System.Object, e As System.Drawing.Printing.PrintPageEventArgs) Handles PrintDocument1.PrintPage
    With DataGridView1
        Dim fmt As StringFormat = New StringFormat(StringFormatFlags.LineLimit)
        fmt.LineAlignment = StringAlignment.Center
        fmt.Trimming = StringTrimming.EllipsisCharacter
        Dim y As Single = e.MarginBounds.Top
        Do While mRow < .RowCount
            Dim row As DataGridViewRow = .Rows(mRow)
            Dim x As Single = e.MarginBounds.Left
            Dim h As Single = 0
            For Each cell As DataGridViewCell In row.Cells
                Dim rc As RectangleF = New RectangleF(x, y, cell.Size.Width, cell.Size.Height)
                e.Graphics.DrawRectangle(Pens.Black, rc.Left, rc.Top, rc.Width, rc.Height)
                If (newpage) Then
                    e.Graphics.DrawString(DataGridView1.Columns(cell.ColumnIndex).HeaderText, .Font, Brushes.Black, rc, fmt)
                Else
                    e.Graphics.DrawString(DataGridView1.Rows(cell.RowIndex).Cells(cell.ColumnIndex).FormattedValue.ToString(), .Font, Brushes.Black, rc, fmt)
                End If
                x += rc.Width
                h = Math.Max(h, rc.Height)
            Next
            newpage = False
            y += h
            mRow += 1
            If y + h > e.MarginBounds.Bottom Then
                e.HasMorePages = True
                mRow -= 1
                newpage = True
                Exit Sub
            End If
        Loop
        mRow = 0
    End With
End Sub

Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button3.Click
    PrintPreviewDialog1.Document = PrintDocument1
    PrintPreviewDialog1.ShowDialog()
End Sub

Answer 2

对于特定列（示例列1,3,4）

Private Sub PrintDocument1_PrintPage(sender As System.Object, e As System.Drawing.Printing.PrintPageEventArgs) Handles PrintDocument1.PrintPage
    Dim custCells As Integer() = {1, 3, 4}
    With DataGridView1
        Dim fmt As StringFormat = New StringFormat(StringFormatFlags.LineLimit)
        fmt.LineAlignment = StringAlignment.Center
        fmt.Trimming = StringTrimming.EllipsisCharacter
        Dim y As Single = e.MarginBounds.Top
        Do While mRow < .RowCount
            Dim row As DataGridViewRow = .Rows(mRow)
            Dim x As Single = e.MarginBounds.Left
            Dim h As Single = 0
            For Each cell As Integer In custCells
                Dim rc As RectangleF = New RectangleF(x, y, row.Cells(cell).Size.Width, row.Cells(cell).Size.Height)
                e.Graphics.DrawRectangle(Pens.Black, rc.Left, rc.Top, rc.Width, rc.Height)
                If (newpage) Then
                    e.Graphics.DrawString(DataGridView1.Columns(cell).HeaderText, .Font, Brushes.Black, rc, fmt)
                Else
                    e.Graphics.DrawString(DataGridView1.Rows(row.Cells(cell).RowIndex).Cells(cell).FormattedValue.ToString(), .Font, Brushes.Black, rc, fmt)
                End If
                x += rc.Width
                h = Math.Max(h, rc.Height)
            Next
            newpage = False
            y += h
            mRow += 1
            If y + h > e.MarginBounds.Bottom Then
                e.HasMorePages = True
                mRow -= 1
                newpage = True
                Exit Sub
            End If
        Loop
        mRow = 0
    End With
End Sub

Answer 3

您可能会发现将数据移动到Excel / Word会非常有用：

    Private Sub tsbtnCopy_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles tsbtnCopy.Click
    dgv01.SuspendLayout()
    dgv01.RowHeadersVisible = False
    If dgv01.SelectedRows.Count = 0 Then dgv01.SelectAll()
    Clipboard.SetDataObject(dgv01.GetClipboardContent())
    dgv01.ClearSelection()
    dgv01.RowHeadersVisible = True
    dgv01.ResumeLayout()
End Sub

或让用户选择全部（单击左上角的单元格）进行复制/粘贴。

如何打印Datagridview在VB中有一个表

3 个答案: