Question

我想编写一个方法来在Perl中提取Windows路径的前两部分。

例如， 'd：\ git_root_tfs \工作站\项目\相互作用\工具\服务器的规则检查工具'

提取为： 'd：\ git_root_tfs \工作站'

sub Split_Location_as_VMPath {
    my $location = shift;
    # ^([d-z]:\\.+?\\.+?)\\
    # ^(?:\\.*\\.*)\\
    if($location ~~ m/^(?:\\.*\\.*)\\/){ # the path drive start from D to E;
        # print "VMPath=$1\n";          
        # push @$vmPathList, $1;
        return Convert_to_Lowercase($1);
    }
    return "Invalid Path $location";
}

如何编写正则表达式？

测试用例：

{
    my $item = Split_Location_as_VMPath('D:\VM\ia7-BGCDev8.1\test.vhd');
    my $expected = Convert_to_Lowercase('D:\VM\ia7-BGCDev8.1');
    ok( $item eq $expected, "Test Split_Location_as_VMPath=$item");

    $item = Split_Location_as_VMPath('E:\Hyper-V-2\ia-int-7.1Beta\test.vhd');
    $expected = Convert_to_Lowercase('E:\Hyper-V-2\ia-int-7.1Beta');
    ok( $item eq $expected, "Test Split_Location_as_VMPath=$item");

    $item = Split_Location_as_VMPath('D:\VM\ia7-int-7.1\test.vhd');
    $expected = Convert_to_Lowercase('D:\VM\ia7-int-7.1');
    ok( $item eq $expected, "Test Split_Location_as_VMPath=$item");

    $item = Split_Location_as_VMPath('D:\VM\ia7-int-8.1B153\test.vhd');
    $expected = Convert_to_Lowercase('D:\VM\ia7-int-8.1B153');
    ok( $item eq $expected, "Test Split_Location_as_VMPath=$item");

    $item = Split_Location_as_VMPath('D:\Hyper-v\IA5-SDE-WIN2K3(Feng Tong)\test.vhd');
    $expected = Convert_to_Lowercase('D:\Hyper-v\IA5-SDE-WIN2K3(Feng Tong)');
    ok( $item eq $expected, "Test Split_Location_as_VMPath=$item");

    $item = Split_Location_as_VMPath('D:\git_root_tfs\WorkStation\Projects\InterACT\Tools\server-rule-checker');
    $expected = Convert_to_Lowercase('D:\git_root_tfs\WorkStation');
    ok( $item eq $expected, "Test Split_Location_as_VMPath=$item");
}

Answer 1

不要使用正则表达式进行文件处理。

而是使用File::Spec或Path::Tiny等模块。

use strict;
use warnings;

use File::Spec;

while (<DATA>) {
    my ($vol, $dir, $file) = File::Spec->splitpath($_);
    my @dirs = File::Spec->splitdir($dir);
    @dirs = @dirs[0..2] if @dirs > 3;
    $dir = File::Spec->catdir(@dirs);
    my $path = File::Spec->catpath($vol, $dir);

    print "$path\n";
}

__DATA__
D:\VM\ia7-BGCDev8.1\test.vhd
E:\Hyper-V-2\ia-int-7.1Beta\test.vhd
D:\VM\ia7-int-7.1\test.vhd
D:\VM\ia7-int-8.1B153\test.vhd
D:\Hyper-v\IA5-SDE-WIN2K3(Feng Tong)\test.vhd
D:\git_root_tfs\WorkStation\Projects\InterACT\Tools\server-rule-checker

输出：

D:\VM\ia7-BGCDev8.1
E:\Hyper-V-2\ia-int-7.1Beta
D:\VM\ia7-int-7.1
D:\VM\ia7-int-8.1B153
D:\Hyper-v\IA5-SDE-WIN2K3(Feng Tong)
D:\git_root_tfs\WorkStation

Answer 2

正确的正则表达式是^（[d-z]：\。+？\。+？）\。

sub Split_Location_as_VMPath {
    my $location = shift;
    # ^([d-z]:\\.+?\\.+?)\\
    # ^(?:\\.*\\.*)\\
    if($location ~~ m/^([D-Z]:\\.+?\\.+?)\\/){ # the path drive start from D to E;
        # print "VMPath=$1\n";          
        # push @$vmPathList, $1;
        return Convert_to_Lowercase($1);
    }
    return "Invalid Path $location";
}

Answer 3

在这种情况下使用正则表达式是学生们有趣的功课。在校外，您应该使用专门用于此任务的标准模块：

use File::Spec;
sub Split_Location_as_VMPath {
    my $location = shift;
    my ($volume, $directories, $file) = File::Spec->splitpath($location);
    my @dirs = File::Spec->splitdir($directories);
    return "Invalid Path $location" unless @dirs > 2;
    return lc File::Spec->catpath($volume, File::Spec->catdir(@dirs[0..2]));    
}

Perl Regex提取前两段windows路径

3 个答案: