XSLT for-each循环表输出

Question

我想用XSLT创建一个表，其中进程阶段是标题，processNo是值。

  <PV_Batch masterBatchNo="KH8944">
    <tempTable processStage="Blending" processNo="KF0285" />
    <tempTable processStage="Coating" processNo="KF0282" />
    <tempTable processStage="Compression" processNo="KF0283" />
    <tempTable processStage="Granulation" processNo="12345" />
    <tempTable processStage="Granulation" processhNo="KF0284" />
    <tempTable processStage="Mixing" processNo="KF0286" />
    <tempTable processStage="mixing" processNo="K12035" />
  </PV_Batch>

Blending | Coating | Compression | Granulation | Mixing
KF0285   | KF0282  | KF0283      | 12345       | KF0286
         |         |             | Kf0284      | K12035

我遇到重复值的问题，每当我重复时，他们就会超出界限，就像这样。

Blending | Coating | Compression | Granulation | Mixing
KF0285   | KF0282  | KF0283      | 12345       | Kf0284  | KF0268  | K12035

这是我的表xslt stylesheet中的代码snippt。

          <xsl:for-each select="//tempTable[generate-id() = generate-id(key('keyComponent', @processStage)[1])]">

              <th width="" align="Left" class="tableHeaderRow">
                  <xsl:value-of select="@processStage" />
                </th>

          </xsl:for-each>

          <tr>
            <xsl:for-each select="tempTable">
              <td align="Left" class="tableNormalRow">
                <xsl:value-of select="@processNo"/>
              </td>
            </xsl:for-each>
          </tr>

Answer 1

显示的代码段中的第二个循环必须执行与标题循环相同的分组：

<xsl:for-each select="//tempTable[generate-id() = generate-id(key('keyComponent', @processStage)[1])]">
      <!-- get current processStage -->
      <xsl:variable name="processStage" select="@processStage"/>
      <td align="Left" class="tableNormalRow">
      <!-- loop over all tempTable belonging to current processStage -->
      <xsl:for-each select="//tempTable[@processStage=$processStage]">
          <p>                  
              <xsl:value-of select="@processNo"/>
          </p>
      </xsl:for-each>
      </td>
</xsl:for-each>

如果processStage有多个值，则会将它们分别放在p中的同一个td中，所以这个表：

Blending | Coating | Compression | Granulation | Mixing
KF0285   | KF0282  | KF0283      | 12345       | KF0286
         |         |             | Kf0284      | K12035

只包含2行。

但是，如果这应该产生一个包含3行的表，那么解决方案会更复杂一些。

---

修改

XSLT 2.0解决方案：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">

<xsl:output indent="yes"/>

<xsl:variable name="processStages" select="distinct-values(//tempTable/@processStage)"/>

<xsl:variable name="maxRows"
    select="max(for $i in $processStages return count(//tempTable[@processStage=$i]))"/>

<xsl:template match="PV_Batch">
    <table>
        <tr>
            <xsl:for-each-group select="tempTable" group-by="@processStage">
                <th width="" align="Left" class="tableHeaderRow">
                    <xsl:value-of select="@processStage"/>
                </th>
            </xsl:for-each-group>
        </tr>

        <xsl:variable name="tempTable" select="tempTable"/>
        <xsl:for-each select="1 to $maxRows">
            <xsl:variable name="pos" select="."/>
            <tr>
                <xsl:for-each select="$processStage">
                    <td>
                        <xsl:value-of select="$tempTable[@processStage=current()][$pos]/@processNo"/>
                    </td>
                </xsl:for-each>
            </tr>
        </xsl:for-each>
    </table>
</xsl:template>
</xsl:stylesheet>

---

XSLT 1.0解决方案：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output indent="yes"/>

<xsl:key name="keyComponent" match="tempTable" use="@processStage"/>

<xsl:template match="PV_Batch">
    <table>
        <tr>
            <xsl:for-each
                select="//tempTable[generate-id() = generate-id(key('keyComponent', @processStage)[1])]">

                <th width="" align="Left" class="tableHeaderRow">
                    <xsl:value-of select="@processStage"/>
                </th>

            </xsl:for-each>
        </tr>

        <xsl:call-template name="tr"/>
    </table>
</xsl:template>

<xsl:template name="tr">
    <xsl:param name="pos" select="1"/>
    <xsl:variable name="temp">
        <xsl:for-each
            select="//tempTable[generate-id() = generate-id(key('keyComponent', @processStage)[1])]">
            <xsl:value-of select="//tempTable[@processStage=current()/@processStage][$pos]/@processNo"/>
        </xsl:for-each>
    </xsl:variable>
    <xsl:if test="normalize-space($temp)!=''">
        <tr>
            <xsl:for-each
                select="//tempTable[generate-id() = generate-id(key('keyComponent', @processStage)[1])]">
                <td>
                    <xsl:value-of select="//tempTable[@processStage=current()/@processStage][$pos]/@processNo"/>
                </td>
            </xsl:for-each>
        </tr>
        <xsl:call-template name="tr">
            <xsl:with-param name="pos" select="$pos + 1"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>