Question

set-difference用作过滤器功能，但仅适用于列表。什么是数组和字符串？这些类型的数据是否有类似的功能？如果没有这样的功能，实现它们的正确方法是什么？

现在我使用这个宏来处理任何序列作为列表（有时它很有用）：

(defmacro treat-as-lists (vars &body body)
  (let ((type (gensym)))
    `(let ((,type (etypecase ,(car vars)
                    (string 'string)
                    (vector 'vector)
                    (list 'list)))
           ,@(mapcar (lambda (x) `(,x (coerce ,x 'list)))
                 vars))
       (coerce (progn ,@body) ,type))))

我的filter：

(defun filter (what where &key key (test #'eql))
  (treat-as-lists (what where)
    (set-difference where what :key key :test test)))

示例：

CL-USER> (filter "cat" "can you take this cat away?")
"n you ke his  wy?"
CL-USER> (filter #(0 1) #(1 5 0 1 9 8 3 0))
#(5 9 8 3)

Answer 1

由于编写适用于所有序列类型的函数通常意味着为列表和向量编写单独的版本，因此使用可在序列上运行的标准函数是值得的。在这种情况下，我们可以使用position和remove-if。我已经颠倒了你的参数的顺序，为了使这个序列差异更像是set-difference，其中第二个参数从第一个参数中减去。

(defun sequence-difference (seq1 seq2 &key (start1 0) end1 (start2 0) end2
                                           key (key1 key) (key2 key)
                                           test test-not)
  "Returns a new sequence of the same type of seq1 that contains the
elements of the subsequence of seq1 designated by start1 and end1, and
in the same order, except for those that appear in the subsequence of
seq2 designated by start2 and end2. Test and test-not are used in the
usual way to elements produced by applying key1 (which defaults to
key) to elements from seq1 and by applying key2 (which defaults to
key) to elements from seq2."
  (flet ((in-seq2 (x)
           (not (null (position x seq2
                                :start start2 :end end2
                                :key key2
                                :test test :test-not test-not)))))
    (remove-if #'in-seq2 
               (subseq seq1 start1 end1)
               :key key1)))

(sequence-difference "can you take this cat away?" #(#\c #\a #\t))
;=> "n you ke his  wy?"

(sequence-difference "can you take this cat away?" #(#\c #\a #\t) :start1 3 :start2 1)
" you ke his c wy?"

请注意，该标准还包括find，它适用于任意序列，但查找返回＆＃34;序列的元素，或nil。＆＃34;如果nil是序列的成员，这会导致歧义。另一方面，位置返回一个索引（它将是一个数字，因此不是nil）或null，因此我们可以可靠地确定一个元素是否是顺序的。

这里有一个重要的区别，因为你总是在这里得到一份副本。其原因是主观的：由于序列函数通常采用开始和结束索引参数，因此在此处包含该功能很不错。但是，如果我们要求(sequence-difference "foobar" "boa" :start1 2)，那么我们想要从＆＃34; foobar＆＃34;＆＃34;＆＃34;＆＃34; obar＆＃34;中删除字符b，o和a。我们应该回报什么？＆＃34;对于＆＃34;或＆＃34; r＆＃34;？也就是说，我们是否包括seq1在指数之外的部分？在这个解决方案中，我决定不这样做，因此我做(remove-if … (subseq seq1 …) …)，而subseq总是复制。另一方面，Set-difference可以返回其list-1或list-2参数（如果适用）。除了在某些病态情况下（例如，空列表），此实现通常不会返回seq1或seq2。

字符串和数组的Set-Difference

1 个答案: