Question

我在perl中使用XML::Bare模块。

我的xml类似于：

<xml>
    <element num="1">
        <num>10</num>
    </element>
    <element num="2">
        <num>20</num>
    </element>
</xml>

我想提取子<num>标记中包含的值。即我想要10 and 20作为输出。但是当我使用$xml->{element}->[$i]->{num}->{value}获取值时，它返回1 adn 2，即返回值num属性而不是子节点。任何人都可以帮助我如何处理属性和子名称相同的情况。

由于

Answer 1

它看起来像XML::Bare中的错误。我在<num>输出中看不到Dumper元素：

use warnings;
use strict;
use XML::Bare;

my $xml = q(
<xml>
    <element num="1">
        <num>10</num>
    </element>
    <element num="2">
        <num>20</num>
    </element>
</xml>
);

my $ob = new XML::Bare( text => $xml );
my $root = $ob->parse();

use Data::Dumper;
$Data::Dumper::Sortkeys=1;
print Dumper($root);

__END__

$VAR1 = {
          '_i' => 0,
          '_pos' => 0,
          '_z' => 0,
          'value' => '
',
          'xml' => {
                     '_i' => 438404290,
                     '_pos' => 1,
                     '_z' => 130,
                     'element' => [
                                    {
                                      '_i' => 438404300,
                                      '_pos' => 2,
                                      '_z' => 64,
                                      'num' => {
                                                 '_att' => 1,
                                                 'value' => '1'
                                               },
                                      'value' => '
        '
                                    },
                                    {
                                      '_i' => 438404359,
                                      '_pos' => 4,
                                      '_z' => 123,
                                      'num' => {
                                                 '_att' => 1,
                                                 'value' => '2'
                                               },
                                      'value' => '
        '
                                    }
                                  ],
                     'value' => '
    '
                   }
        };

You could submit a bug report

以下是XML::Twig的解决方案：

use warnings;
use strict;
use XML::Twig;

my $xml = q(
<xml>
    <element num="1">
        <num>10</num>
    </element>
    <element num="2">
        <num>20</num>
    </element>
</xml>
);

my $twig= XML::Twig->new(twig_handlers => { element => \&elem });
$twig->parse($xml);

sub elem {
    my( $twig, $ele)= @_;
    my $att = $ele->att('num');
    my $num = $ele->first_child('num')->text();
    print "$att $num\n";
}

__END__

1 10
2 20

Answer 2

如果使用XML::Bare或XML::Simple，则应仅限于最基本的XML读取。鉴于您的数据具有属性，并且共享名称的子节点未能通过该限制。

事实上，除非有一个特定的理由，否则应该坚持使用更现代的XML解析器，例如XML::Twig和XML::LibXML以及XPath支持的全部功能。

以下两个模块解析您的XML：

use strict;
use warnings;

use XML::LibXML;
use XML::Twig;

my $data = do {local $/; <DATA>};

print "XML::LibXML\n";
my $xml = XML::LibXML->load_xml(string => $data);
for my $node ($xml->findnodes('//element/num')) {
    print $node->textContent(), "\n";
}

print "XML::Twig\n";
my $t = XML::Twig->new( 
    twig_handlers => {
        '//element/num' => sub { print $_->text(), "\n" },
    },
);
$t->parse( $data );

__DATA__
<xml>
    <element num="1">
        <num>10</num>
    </element>
    <element num="2">
        <num>20</num>
    </element>
</xml>

输出：

XML::LibXML
10
20
XML::Twig
10
20

XML :: Bare perl的问题

2 个答案: