Question

如果我使用稀疏（i，j，k）构造函数构造了稀疏矩阵，那么如何对矩阵的列进行归一化（以便每列总和为1）？在创建矩阵之前，我无法有效地规范化条目，因此感谢任何帮助。谢谢！

Answer 1

最简单的方法是按列总和进行广播划分：

julia> A = sprand(4,5,.5)
       A./sum(A,1)
4x5 Array{Float64,2}:
 0.0        0.0989976  0.0        0.0       0.0795486
 0.420754   0.458653   0.0986313  0.0       0.0
 0.0785525  0.442349   0.0        0.856136  0.920451
 0.500693   0.0        0.901369   0.143864  0.0

...但看起来它还没有针对稀疏矩阵进行优化，而是回落到一个完整的矩阵。因此，迭代列的简单循环可以解决问题：

julia> for (col,s) in enumerate(sum(A,1))
         s == 0 && continue # What does a "normalized" column with a sum of zero look like?
         A[:,col] = A[:,col]/s
       end
       A
4x5 sparse matrix with 12 Float64 entries:
    [2, 1]  =  0.420754
    [3, 1]  =  0.0785525
    [4, 1]  =  0.500693
    [1, 2]  =  0.0989976
    [2, 2]  =  0.458653
    [3, 2]  =  0.442349
    [2, 3]  =  0.0986313
    [4, 3]  =  0.901369
    [3, 4]  =  0.856136
    [4, 4]  =  0.143864
    [1, 5]  =  0.0795486
    [3, 5]  =  0.920451

julia> sum(A,1)
1x5 Array{Float64,2}:
 1.0  1.0  1.0  1.0  1.0

这完全在稀疏矩阵内完成并且就地完成（尽管它仍然为每个列切片分配新的稀疏矩阵）。

Answer 2

给定矩阵A（无论它是否稀疏）按任何维度

进行归一化

 A ./ sum(A,1) or  A ./ sum(A,2)

表明它有效：

A = sprand(10,10,0.3)   
println(sum(A,1))
println(A ./ sum(A,1))

只有警告

A[1,:] = 0
println(A ./ sum(A,1))

你可以看到第1列现在只包含NaN，因为我们除以零。我们最终得到的是Matrix而不是稀疏矩阵。

另一方面，人们可以快速为您的问题找到一个有效的专业解决方案。

function normalize_columns(A :: SparseMatrixCSC)
          sums = sum(A,1)
          I,J,V = findnz(A)
          for idx in 1:length(V)
            V[idx] /= sums[J[idx]]
          end
          sparse(I,J,V)
end

@Matt B在我打字的时候提出了一个非常相似的答案：）

Answer 3

请记住，Julia中的稀疏矩阵是压缩列形式。所以你可以直接访问数据：

for col = 1 : size(A, 2)
  i = A.colptr[col]
  k = A.colptr[col+1] - 1
  n = i <= k ? norm(A.nzval[i:k]) : 0.0  # or whatever you like
  n > 0.0 && (A.nzval[i:k] ./= n)
end

Answer 4

以下内容给出了您想要的内容： A =抛出（4,5,0.5） B = A./sparse(sum(A,1））

问题是sum（A，1）给出1x5密集阵列，因此通过./运算符与稀疏矩阵A组合得到密集阵列。所以你需要强制它是稀疏类型。或者你可以输入稀疏的（A ./ sum（A，1））。

Answer 5

# get the column sums of A
S = vec(sum(A,1))

# get the nonzero entries in A. ei is row index, ej is col index, ev is the value in A
ei,ej,ev = findnz(A)

# get the number or rows and columns in A
m,n = size(A)

# create a new normalized matrix. For each nonzero index (ei,ej), its new value will be
# the old value divided by the sum of that column, which can be obtained by S[ej]
A_normalized = sparse(ei,ej,ev./S[ej],m,n)

在Julia中，我如何对稀疏矩阵进行列标准化？

5 个答案: