Question

在Fsharp应用程序中，我将几个联合案例类型定义为

type A = A of String
type B = B of String
type C = C of String

我想定义一个函数来从union case实例中提取值。

let getValue( ctor: String-> 'a) = 
   ...implementation here

反正有没有完成这样的任务？感谢。

Answer 1

我们说你有：

type A = A of string
type B = B of string
type C = C of string

let a = A "hello"
let b = B "world"
let c = C "!"

有很多方法可以提取这些值，这里有一些：

个人解包者

let getValueA (A v) = v
let getValueB (B v) = v
let getValueC (C v) = v

let valueOfA = getValueA a
let valueOfB = getValueB b
let valueOfC = getValueC c

方法重载

type T =
    static member getValue (A v) = v
    static member getValue (B v) = v
    static member getValue (C v) = v

let valueOfA = T.getValue a
let valueOfB = T.getValue b
let valueOfC = T.getValue c

功能过载

type GetValue = GetValue with
    static member ($) (GetValue, (A v)) = v
    static member ($) (GetValue, (B v)) = v
    static member ($) (GetValue, (C v)) = v

let inline getValue x : string = GetValue $ x

let valueOfA = getValue a
let valueOfB = getValue b
let valueOfC = getValue c

<强>反射

open Microsoft.FSharp.Reflection
let getValue a =  
    FSharpValue.GetUnionFields (a, a.GetType())
        |> snd
        |> Seq.head
        :?> string

let valueOfA = getValue a
let valueOfB = getValue b
let valueOfC = getValue c

重新设计您的DU

type A = A
type B = B
type C = C

type MyDU<'a> = MyDU of 'a * string

let a = MyDU (A, "hello")
let b = MyDU (B, "world")
let c = MyDU (C, "!"    )

let getValue (MyDU (_, v)) = v

let valueOfA = getValue a
let valueOfB = getValue b

使用界面重新设计

type IWrapped<'a> =
    abstract getValue: 'a

type A = A of string with interface IWrapped<string> with member t.getValue = let (A x) = t in x        
type B = B of string with interface IWrapped<string> with member t.getValue = let (B x) = t in x
type C = C of string with interface IWrapped<string> with member t.getValue = let (C x) = t in x

let valueOfA = (a :> IWrapped<string>).getValue

从工会案例中提取价值

1 个答案: