Question

我是XSLT的新手，我无法解决以下问题：

我有一个像这样的xml文件：

<root>
    <subset>
        <e id="A"></e>
        <e id="C"></e>
    </subset>

    <data>
        <info id="A" order="3" name="ANode"></info>
        <info id="B" order="4" name="BNode"></info>
        <info id="C" order="1" name="CNode"></info>
        <info id="D" order="2" name="DNode"></info>
    </data>
</root>

我想制作这个：

<root>
    <newnode id="C" order="1" name="CNode"></newnode>
    <newnode id="A" order="3" name="ANode"></newnode>
</root>

正如您所看到的那样，想法是通过检索相应的信息来“完成”ID的子集，并根据<data>上指定的顺序对它们进行排序。

请注意，<data>应该有很多子节点。

另外，我将节点与来自id子集的<data>元素的信息分开，因为我将有许多子集，我不希望“无处不在”重复信息。

提前致谢。

Answer 1

交叉引用要求使用密钥：

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output indent="yes"/>

  <xsl:key name="k1" match="info" use="@id"/>

  <xsl:template match="root">
    <xsl:copy>
      <xsl:apply-templates select="subset/e">
        <xsl:sort select="key('k1', @id)/@order" data-type="number"/>
      </xsl:apply-templates>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="e">
    <newnode id="{@id}" order="{key('k1', @id)/@order}" name="{key('k1', @id)/@name}"/>
  </xsl:template>

</xsl:stylesheet>

这应该适用于您提供的输入样本。

Answer 2

您还可以根据实际数据可能需要的其他内容来关闭子集。

<xsl:output indent="yes" />

<xsl:key name="subset" match="e" use="@id" />

<xsl:template match="/">
    <root>
    <xsl:for-each select="//info[count(key('subset',@id)[1]) &gt; 0]">
        <xsl:sort select="@order" data-type="number" />
        <newnode id="{@id}" order="{@order}" name="{@name}" />
    </xsl:for-each>
    </root>
</xsl:template>

如何获取信息和排序，使用XSLT仅使用标识符的元素子集？

2 个答案: