Question

TDBCtrlGrid根本不会对鼠标滚轮做出反应。

我试过了：

procedure TForm1.FormMouseWheel(Sender: TObject;
  Shift: TShiftState; WheelDelta: Integer; MousePos: TPoint;
  var Handled: Boolean);
begin
  if DBCtrlGrid1.ClientRect.Contains(DBCtrlGrid1.ScreenToClient(MousePos)) then
  begin
    DBCtrlGrid1.ScrollBy(0, WheelDelta);
    Handled := True;
  end;
end;

控制网格现在滚动，但它不会改变DataSet中的位置，而是将其内容移出客户端rect，看起来非常难看。

如何在TDBCtrlGrid上启用鼠标滚轮滚动？

Answer 1

作为一种解决方法，您可以改为滚动数据集：

procedure TForm1.FormMouseWheel(Sender: TObject;
  Shift: TShiftState; WheelDelta: Integer; MousePos: TPoint;
  var Handled: Boolean);
var
  I: Integer;
  Grid: TDBCtrlGrid;
  DataSet: TDataSet;
begin
  Grid := DBCtrlGrid1;
  if not Grid.ClientRect.Contains(Grid.ScreenToClient(MousePos)) then
    Exit;
  if not Assigned(Grid.DataSource) then
    Exit;
  DataSet := Grid.DataSource.DataSet;
  if DataSet = nil then
    Exit;
  for I := 0 to Abs(WheelDelta div 256) - 1 do 
  begin
    if WheelDelta > 0 then
      DataSet.Prior
    else
      DataSet.Next;
  end;
  Handled := True;
end;

Answer 2

如果您的表单上还具有隐藏的DBGrid，并且钩接到了相同的数据源，则有一种更简便的方法。在DBCtrlGrid的click事件中：

DBCtrlGrid.setfocus;

只要集中注意力，DBGrid似乎就会收到鼠标滚轮事件。然后，随着记录的更改，DBCtrlGrid会很好地滚动。

如何在TDBCtrlGrid上启用鼠标滚轮滚动？

2 个答案: